dev-python/opentelemetry-semantic-conventions: new package, add 1.23.0

Signed-off-by: Alfred Wingate <parona@protonmail.com>
Signed-off-by: Michał Górny <mgorny@gentoo.org>

3 files changed, 90 insertions, 0 deletions

diff --git a/dev-python/opentelemetry-semantic-conventions/Manifest b/dev-python/opentelemetry-semantic-conventions/Manifest
new file mode 100644
index 000000000000..82f3ae2ef0af
--- /dev/null
+++ b/dev-python/opentelemetry-semantic-conventions/Manifest
@@ -0,0 +1 @@
+DIST opentelemetry-python-1.23.0.gh.tar.gz 523456 BLAKE2B 94047e0d806ce17f0116fd6343daeecbf738c41e3e1cc1cbf8af9a0b1c44b29cecbc597011a7ffe15ffc656f2744750d9117d63bdaa77c7971248f58f9580c8e SHA512 8a2cb94d774db15eb6bb7fd97d5b761d35066779072c0ce0cf51b6d1083d115120b932598c0da2efb20060e8a4c65415a74f508011ccca7242e2d79705f0c246
diff --git a/dev-python/opentelemetry-semantic-conventions/metadata.xml b/dev-python/opentelemetry-semantic-conventions/metadata.xml
new file mode 100644
index 000000000000..4f1084df480f
--- /dev/null
+++ b/dev-python/opentelemetry-semantic-conventions/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<maintainer type="person">
+		<email>parona@protonmail.com</email>
+		<name>Alfred Wingate</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">opentelemetry-semantic-conventions</remote-id>
+		<remote-id type="github">open-telemetry/opentelemetry-python</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.23.0.ebuild b/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.23.0.ebuild
new file mode 100644
index 000000000000..321404550b34
--- /dev/null
+++ b/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.23.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="opentelemetry-python-${PV}"
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenTelemetry Semantic Conventions"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-sdk/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/deprecated[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/importlib-metadata[${PYTHON_USEDEP}]
+		dev-python/iniconfig[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pluggy[${PYTHON_USEDEP}]
+		dev-python/py-cpuinfo[${PYTHON_USEDEP}]
+		dev-python/py[${PYTHON_USEDEP}]
+		dev-python/tomli[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/wrapt[${PYTHON_USEDEP}]
+		dev-python/zipp[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Use the same version with all opentelemetry components
+	# https://github.com/gentoo/gentoo/pull/35962#issuecomment-2025466313
+	sed -i -e "s/\(__version__ =\) .*/\1 \"${PV}\"/" src/opentelemetry/semconv/version.py || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-api opentelemetry-sdk tests/opentelemetry-test-utils ; do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest
+}