media-libs/openimageio: bump to 2.2.9.0

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 139 insertions, 0 deletions

diff --git a/media-libs/openimageio/Manifest b/media-libs/openimageio/Manifest
index f3b206c56038..8a898c0f3c55 100644
--- a/media-libs/openimageio/Manifest
+++ b/media-libs/openimageio/Manifest
@@ -1 +1,2 @@
 DIST openimageio-2.2.8.0.tar.gz 29201949 BLAKE2B b77e42dddfaa6a8dff174b89e43c7de158efcae0e851037a97f1f46127f5cda458bdc7b64172c1fe64236d5ace351c9a432c2e857467c7f83b59dc9f6670fbeb SHA512 7bb94832734b4354d961003ec7f85fa30e4a69d7f825c5668a0230d857f8c137dd522730ec5089db012f0d843fc67368c731458a3d6de9ae41dabfb4cc30592e
+DIST openimageio-2.2.9.0.tar.gz 29216767 BLAKE2B 92c17de4687d3d7390602a02dedc5afc1258018cef98e671977fb706c3fe1e80c30416fff89ff1b9936f0f1426eab0136e130efb4a41d7378d3f1eb77eab193a SHA512 d03500c5a9f4f1417c5629098254d1bbf032a17228898e5f087e4a5d0988f806537d3ab538366e64c51172568c3688389ab29b641fdaaf7208bf939cb859e06d
diff --git a/media-libs/openimageio/openimageio-2.2.9.0.ebuild b/media-libs/openimageio/openimageio-2.2.9.0.ebuild
new file mode 100644
index 000000000000..2ddc9e37ad5f
--- /dev/null
+++ b/media-libs/openimageio/openimageio-2.2.9.0.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit cmake python-single-r1
+
+DESCRIPTION="A library for reading and writing images"
+HOMEPAGE="https://sites.google.com/site/openimageio/ https://github.com/OpenImageIO"
+SRC_URI="https://github.com/OpenImageIO/oiio/archive/Release-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/oiio-Release-${PV}"
+
+LICENSE="BSD"
+SLOT="0/2.2"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+X86_CPU_FEATURES=(
+	aes:aes sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="dicom doc ffmpeg field3d gif jpeg2k opencv opengl openvdb ptex python qt5 raw +truetype ${CPU_FEATURES[@]%:*}"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# test data in separate repo
+# second repo has no structure whatsoever
+RESTRICT="test"
+
+BDEPEND="
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-bibtexextra
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-fontutils
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexextra
+	)
+"
+RDEPEND="
+	>=dev-libs/boost-1.62:=
+	dev-cpp/robin-map
+	dev-libs/libfmt:=
+	dev-libs/pugixml:=
+	>=media-libs/ilmbase-2.2.0-r1:=
+	>=media-libs/libheif-1.7.0:=
+	media-libs/libpng:0=
+	>=media-libs/libwebp-0.2.1:=
+	media-libs/opencolorio:=
+	>=media-libs/openexr-2.2.0-r2:=
+	media-libs/tiff:0=
+	sys-libs/zlib:=
+	virtual/jpeg:0
+	dicom? ( sci-libs/dcmtk )
+	ffmpeg? ( media-video/ffmpeg:= )
+	field3d? ( media-libs/Field3D:= )
+	gif? ( media-libs/giflib:0= )
+	jpeg2k? ( >=media-libs/openjpeg-2.0:2= )
+	opencv? ( media-libs/opencv:= )
+	opengl? (
+		media-libs/glew:=
+		virtual/glu
+		virtual/opengl
+	)
+	openvdb? (
+		dev-cpp/tbb:=
+		media-gfx/openvdb:=
+	)
+	ptex? ( media-libs/ptex:= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+		opengl? ( dev-qt/qtopengl:5 )
+	)
+	raw? ( media-libs/libraw:= )
+	truetype? ( media-libs/freetype:2= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES.md CREDITS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+	cmake_comment_add_subdirectory src/fonts
+}
+
+src_configure() {
+	# Build with SIMD support
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local mycmakeargs=(
+		-DVERBOSE=ON
+		-DOIIO_BUILD_TESTS=OFF
+		-DBUILD_DOCS=$(usex doc)
+		-DINSTALL_DOCS=$(usex doc)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_DCMTK=$(usex dicom)
+		-DUSE_EXTERNAL_PUGIXML=ON
+		-DUSE_JPEGTURBO=ON
+		-DUSE_NUKE=OFF # not in Gentoo
+		-DUSE_FFMPEG=$(usex ffmpeg)
+		-DUSE_FIELD3D=$(usex field3d)
+		-DUSE_GIF=$(usex gif)
+		-DUSE_OPENJPEG=$(usex jpeg2k)
+		-DUSE_OPENCV=$(usex opencv)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_OPENVDB=$(usex openvdb)
+		-DUSE_PTEX=$(usex ptex)
+		-DUSE_PYTHON=$(usex python)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_LIBRAW=$(usex raw)
+		-DUSE_FREETYPE=$(usex truetype)
+		-DUSE_SIMD=$(local IFS=','; echo "${mysimd[*]}")
+	)
+
+	cmake_src_configure
+}