media-libs/harfbuzz: add 8.3.1

and sync live to drop stale dev-libs/gobject-introspection-common dep which
was for the autotools days.

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 104 insertions, 4 deletions

diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
index e70ec21b8641..aa44788955eb 100644
--- a/media-libs/harfbuzz/Manifest
+++ b/media-libs/harfbuzz/Manifest
@@ -1 +1,2 @@
 DIST harfbuzz-8.3.0.tar.xz 19002808 BLAKE2B 3749d2ff7955e135cf0d740bf6fe8b5c20a6bbf171480a29e6ae14fde8c26e1457506278b8c66e3b9630cbeb006874c19075c784a575e490c41297274a27fe59 SHA512 6b8753c0b55d34a1a46a64466b9b0de8bc4748c42b29fa9463616a5f48db08ceb4a80cce416e10861778b98dc96d0638d9dd8d7204e404662154f419f3f61f21
+DIST harfbuzz-8.3.1.tar.xz 19228384 BLAKE2B 84a371284a281a19c3b1f6f9a47dd92060e6fe2b6f4d2469e45e5dbce58b0b151414fa70057bca352a626d8b852ac251168a9749ccac5436ee06280165d31821 SHA512 47bb8150faf215d317a434f78c3029261924aae5ff479fbd3a5d62dbbbfce159460fcbc6f53c3c8ec85b09fad5ae0c9d591d67a0ca70424f43ed5b7849eef4ea
diff --git a/media-libs/harfbuzz/harfbuzz-8.3.1.ebuild b/media-libs/harfbuzz/harfbuzz-8.3.1.ebuild
new file mode 100644
index 000000000000..d4d3515eea9d
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-8.3.1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit flag-o-matic meson-multilib python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/harfbuzz/harfbuzz.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/harfbuzz/harfbuzz/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="Old-MIT ISC icu"
+# 0.9.18 introduced the harfbuzz-icu split; bug #472416
+# 3.0.0 dropped some unstable APIs; bug #813705
+# 6.0.0 changed libharfbuzz-subset.so ABI
+SLOT="0/6.0.0"
+
+IUSE="+cairo debug doc experimental +glib +graphite icu +introspection test +truetype"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:=[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-util/glib-utils )
+"
+
+src_prepare() {
+	default
+
+	xdg_environment_reset
+
+	# bug #726120
+	sed -i \
+		-e '/tests\/macos\.tests/d' \
+		test/shape/data/in-house/Makefile.sources \
+		|| die
+
+	# bug #790359
+	filter-flags -fexceptions -fthreadsafe-statics
+
+	if ! use debug ; then
+		append-cppflags -DHB_NDEBUG
+	fi
+
+	# bug #762415
+	local pyscript
+	for pyscript in $(find -type f -name "*.py") ; do
+		python_fix_shebang -q "${pyscript}"
+	done
+}
+
+multilib_src_configure() {
+	# harfbuzz-gobject only used for introspection, bug #535852
+	local emesonargs=(
+		-Dcoretext=disabled
+		-Dchafa=disabled
+		-Dwasm=disabled
+
+		$(meson_feature cairo)
+		$(meson_feature glib)
+		$(meson_feature graphite graphite2)
+		$(meson_feature icu)
+		$(meson_feature introspection gobject)
+		$(meson_feature test tests)
+		$(meson_feature truetype freetype)
+
+		$(meson_native_use_feature doc docs)
+		$(meson_native_use_feature introspection)
+		# Breaks building tests..
+		#$(meson_native_use_feature utilities)
+
+		$(meson_use experimental experimental_api)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# harfbuzz:src / check-static-inits times out on hppa
+	meson_src_test --timeout-multiplier 5
+}
diff --git a/media-libs/harfbuzz/harfbuzz-9999.ebuild b/media-libs/harfbuzz/harfbuzz-9999.ebuild
index c114ab1668f9..d4d3515eea9d 100644
--- a/media-libs/harfbuzz/harfbuzz-9999.ebuild
+++ b/media-libs/harfbuzz/harfbuzz-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -36,9 +36,7 @@ RDEPEND="
 	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
 	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
 "
-DEPEND="${RDEPEND}
-	>=dev-libs/gobject-introspection-common-1.34
-"
+DEPEND="${RDEPEND}"
 BDEPEND="
 	${PYTHON_DEPS}
 	virtual/pkgconfig