dev-python/tempest: Bump to 37.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index f79bcc5498f2..d1082e08ad28 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-36.0.0.tar.gz 1137446 BLAKE2B f645b35b42252dc2bb4b7e1a3f609ee31e76d60e952c2ebb2a404b5f2e40b449aed0815631e922dffc71bd1598a5554277b851f54b99a37a1af328de171ec3ac SHA512 1d931052aa3fd9c76dc6ea23f861d43842877158307877235f5fc64d8a2a0a65dedefebec7ef5a7153aad7ccc3fc9954a882696adbaa6800af9ea2eb652790dc
+DIST tempest-37.0.0.tar.gz 1146330 BLAKE2B 51acf1e0e8ce3a95d54e7b916100c32cee34f9546166fd43883f9bd5c4d4aad7d846b17c4c805392b64b9a0a02fea903c59b799f14d7e459d337eeb11c62cb6a SHA512 1de0e26c86a59c0e3f3dc494d4fdb4d3ca5ab215c1d52b34b4618e9c939ecd59b29c09bccb31bed7911517edce4cae4f9acbd2d1e28be75b0305850230528c67
diff --git a/dev-python/tempest/tempest-37.0.0.ebuild b/dev-python/tempest/tempest-37.0.0.ebuild
new file mode 100644
index 000000000000..6821a436d77d
--- /dev/null
+++ b/dev-python/tempest/tempest-37.0.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	stestr --test-path ./tempest/tests run --concurrency="$(makeopts_jobs)" ||
+		die "Tests failed for ${EPYTHON}"
+}