sys-kernel/gentoo-kernel-bin: patch 6.5.3 for NFS issue

Bring us up to genpatches-6.5-5 for a backported NFS fix.

Bug: https://bugs.gentoo.org/914204
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 136 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index b745b1487857..06364ad2a7ef 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -56,6 +56,10 @@ DIST gentoo-kernel-6.5.3-1.amd64.gpkg.tar 83578880 BLAKE2B 9413bc88b067e91939378
 DIST gentoo-kernel-6.5.3-1.arm64.gpkg.tar 73175040 BLAKE2B c17faa62cb94999d051a5764df7f3e398795dbcd0bfe13b23582a15d2c59188eff00c5d11cd376d9dc1a8c80629746948cfa62c2a337b3a0bb6382482f797ea9 SHA512 4ae0a14d7938ca325680107a094a7d5a58b9139ae28a4916493c5e114c50dbbccaedac3bb1b0012af6ef408ca844fe3c6b7ef52c234eebb92f92b0a1ae44be5e
 DIST gentoo-kernel-6.5.3-1.ppc64le.gpkg.tar 64460800 BLAKE2B 65ccb9381be1572710ded7a369eb665dcd2ffc9b1058e7133fff7a9cccb4e2e159eb4eb9e7b437fd883b92acbe9b54390ecbaa4ee40e8aea9bb37f86687046bd SHA512 0696d19cfb48b465621f2c10fd27c44ccfae37d5bd80fd84f37255ad76c8d7475700784d77ca0ffa981feefe4bc82b920bc78557745634e74bec4c5ac6b38f41
 DIST gentoo-kernel-6.5.3-1.x86.gpkg.tar 67338240 BLAKE2B 30f4105c3aa0fd516eba549705294030bd5757e4467490c6f6b95b4444ed89b5575768a15bb64a61c17a362a51505243254bcbbc806af18709553407d919dac2 SHA512 9fd0760261c40ae3cb9adf75ff457866c11454f72a79f836779a533640b5fa9d568090505be3cb502a00aaed6581b8c387f05a36b72c00ded83c2299c0340754
+DIST gentoo-kernel-6.5.3-r1-1.amd64.gpkg.tar 83630080 BLAKE2B eb83ecca1f1543f979dcd086bec0430c19d0425af069f118d49016a04f603882ed0702d7115f3a1a6c81b828b19277cfa2c71e982f6f504e51060f44041d9dd4 SHA512 8b38bb83cacd6e2d16041fdadc8f85e8d85dc7b971d65edb390170586f5f62d3da44dc4c8864032fc6aa7840fb138bc6c055066653aefe163a90f1708f4fead5
+DIST gentoo-kernel-6.5.3-r1-1.arm64.gpkg.tar 73175040 BLAKE2B 8647a368d033d41ed560abb49e23d1bd7305df88902c368b86d9b150cd0f25478f60cb20b97046dbbebe034862a290402b24df11aa1f8421ed547c2cdb48771e SHA512 12f825fe466cba5bea9336a01e68b08032d7dc8eb5d098238d295d6a3f54e404227a2ba754525881974cbf9996fedaa14c0e65387522f96ca3e6c8e7d8bb54a8
+DIST gentoo-kernel-6.5.3-r1-1.ppc64le.gpkg.tar 64450560 BLAKE2B 8adf4b4e64a5cd52639ebf3f1cc45579540f2fcf5bec806d620d0751258a490a9e48586fe92ff84fd99d443a51eccfe4ab6525c3acb627786c57475659819c72 SHA512 550514639606a16aa7094799380b93a402eac07f57bd752c5a5e33520089fd26d0ac446ddfe02de2a94e9a31b3188666ea8b8fd0b606c51b15711771f3917f63
+DIST gentoo-kernel-6.5.3-r1-1.x86.gpkg.tar 67317760 BLAKE2B 93dd9163c763a75919d1207335b5a0a4f23630996981c66b43ef4593cb068975107e7e2b7d25e0c31a59a9e92adb663a110f1ba62221e6dda45a8464aa0142d3 SHA512 e4ef0d789bf62d0f837ce826d4acfdefed515450aa3d869c3fe2d052158d322fff3038a9cfb9de3f425e5f254a8ebf623b473df27c24a4c88f5e1690e988c565
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.15.tar.xz 121913744 BLAKE2B 3921274b23f7938abdf3ed9334534b4581e13d7484303d3a5280eddb038999aaa8b836666a487472d9c4a219af0f06b9fecccaf348fb5510ab8762f4ef4b7e83 SHA512 d25ad40b5bcd6a4c6042fd0fd84e196e7a58024734c3e9a484fd0d5d54a0c1d87db8a3c784eff55e43b6f021709dc685eb0efa18d2aec327e4f88a79f405705a
 DIST linux-5.4.tar.xz 109441440 BLAKE2B 193bc4a3147e147d5529956164ec4912fad5d5c6fb07f909ff1056e57235834173194afc686993ccd785c1ff15804de0961b625f3008cca0e27493efc8f27b13 SHA512 9f60f77e8ab972b9438ac648bed17551c8491d6585a5e85f694b2eaa4c623fbc61eb18419b2656b6795eac5deec0edaa04547fc6723fbda52256bd7f3486898f
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.5.3-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.5.3-r1.ebuild
new file mode 100644
index 000000000000..26b296bcb3b6
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-6.5.3-r1.ebuild
@@ -0,0 +1,132 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KERNEL_EFI_ZBOOT=1
+KERNEL_IUSE_SECUREBOOT=1
+inherit kernel-install toolchain-funcs unpacker
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${PF/-bin}-1
+
+DESCRIPTION="Pre-built Linux kernel with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.amd64.gpkg.tar
+	)
+	arm64? (
+		https://dev.gentoo.org/~mgorny/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.arm64.gpkg.tar
+	)
+	ppc64? (
+		https://dev.gentoo.org/~mgorny/binpkg/ppc64le/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.ppc64le.gpkg.tar
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/kernel/sys-kernel/gentoo-kernel/${BINPKG}.gpkg.tar
+			-> ${BINPKG}.x86.gpkg.tar
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}
+"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	app-alternatives/yacc
+"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP="$(tc-getSTRIP)"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH="$(tc-arch-kernel)"
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "${BINPKG}/image/usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/${BINPKG}/image/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"${BINPKG}/image/lib/modules/${KPV}"
+}
+
+src_install() {
+	mv "${BINPKG}"/image/{lib,usr} "${ED}"/ || die
+
+	# FIXME: requires proper mount-boot
+	if [[ -d ${BINPKG}/image/boot/dtbs ]]; then
+		mv "${BINPKG}"/image/boot "${ED}"/ || die
+	fi
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+
+	# Modules were already stripped before signing
+	dostrip -x /lib/modules
+}