media-video/avidemux: Bump avidemux-2.6.20 and update to EAPI 6

Package-Manager: Portage-2.3.6, Repoman-2.3.2

4 files changed, 217 insertions, 45 deletions

diff --git a/media-video/avidemux/Manifest b/media-video/avidemux/Manifest
index 418a75235847..6f017f59f92b 100644
--- a/media-video/avidemux/Manifest
+++ b/media-video/avidemux/Manifest
@@ -1 +1,2 @@
+DIST avidemux_2.6.20.tar.gz 20172362 SHA256 03c6cb7fc9eb74688b4fcd5eb654ed7b9c4ffc717a72cc09b08a2d10cdc7ef9f SHA512 d01d0fc24a3004770bd3923c2debc4fa2752eb71df08cfe423746b9c44a2562ca01d82965ed2563b99572a4bed8034b79487199ce330208b51a3b7f87ccf7103 WHIRLPOOL 2e2dc21bed49eeb0cdfefe75fe51f6a84226e7e8e80b063bc0b3d8711a6b91db710611dc0ec06575be69ec8e24f2f9e5b5eb363b9c095267729e85e162a4ce38
 DIST avidemux_2.6.8.tar.gz 17380534 SHA256 02998c235a89894d184d745c94cac37b78bc20e9eb44b318ee2bb83f2507e682 SHA512 57a4042f1a9d46462850871d36950215c5ffb5b66ce2f2cde09d747e946c05adb7a550ac7763c96f4c1bcb2c39881407d9d88bc64c93053741091751495ba0b0 WHIRLPOOL 29f8a6039d82e686e8dfbfc7b23658921834238a4cc6c4de338afdfdc032a9a7cba1c8236789aa6dbcab318ec14c344c19563f153e6cbd63cd265c5fb15b44b6
diff --git a/media-video/avidemux/avidemux-2.6.20.ebuild b/media-video/avidemux/avidemux-2.6.20.ebuild
new file mode 100644
index 000000000000..2ad1ffeee1b4
--- /dev/null
+++ b/media-video/avidemux/avidemux-2.6.20.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PLOCALES="ca cs de el es fr it ja pt_BR ru sr sr@latin tr"
+
+inherit cmake-utils l10n
+
+DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/${PN}"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
+IUSE="debug opengl nls nvenc qt4 qt5 sdl vaapi vdpau video_cards_fglrx xv"
+
+if [[ ${PV} == *9999* ]] ; then
+	MY_P="${P}"
+	EGIT_REPO_URI="https://github.com/mean00/avidemux2.git"
+
+	inherit git-r3
+else
+	MY_P="${PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DEPEND="
+	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,video_cards_fglrx?,xv?,nvenc?]
+	opengl? ( virtual/opengl:0 )
+	qt4? ( >=dev-qt/qtgui-4.8.3:4 )
+	qt5? ( dev-qt/qtgui:5 )
+	vaapi? ( x11-libs/libva:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
+	video_cards_fglrx? (
+		|| ( >=x11-drivers/ati-drivers-14.12-r3
+			x11-libs/xvba-video:0 )
+		)"
+RDEPEND="
+	$DEPEND
+	nls? ( virtual/libintl:0 )
+"
+PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt4?,qt5?]"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	processes="buildCli:avidemux/cli"
+	use qt4 && processes+=" buildQt4:avidemux/qt4"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake-utils_src_prepare
+	done
+
+	# Fix icon name -> avidemux-2.6.png
+	sed -i -e "/^Icon/ s:${PN}:${PN}-2.6:" ${PN}2.desktop || die "Icon name fix failed."
+
+	# The desktop file is broken. It uses avidemux2 instead of avidemux3
+	# so it will actually launch avidemux-2.5 if it is installed.
+	sed -i -e "/^Exec/ s:${PN}2:${PN}3:" ${PN}2.desktop || die "Desktop file fix failed."
+	sed -i -re '/^Exec/ s:(avidemux3_)gtk:\1qt'$(usex qt5 5 4)':' ${PN}2.desktop || die "Desktop file fix failed."
+
+	# Fix QA warnings that complain a trailing ; is missing and Application is deprecated.
+	sed -i -e 's/Application;AudioVideo/AudioVideo;/g' ${PN}2.desktop || die "Desktop file fix failed."
+
+	# Now rename the desktop file to not collide with 2.5.
+	mv ${PN}2.desktop ${PN}-2.6.desktop || die "Collision rename failed."
+
+	# Remove "Build Option" dialog because it doesn't reflect what the GUI can or has been built with. (Bug #463628)
+	sed -i -e '/Build Option/d' avidemux/common/ADM_commonUI/myOwnMenu.h || die "Couldn't remove \"Build Option\" dialog."
+}
+
+src_configure() {
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	local mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR='${S}'
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+	)
+
+	if use qt5 ; then
+		mycmakeargs+=( -DENABLE_QT5="$(usex qt5)" )
+	fi
+
+	if use debug ; then
+		mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+	fi
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake-utils_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_install
+	done
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_cli ]] ; then
+		fperms +x /usr/bin/avidemux3_cli
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_jobs ]] ; then
+		fperms +x /usr/bin/avidemux3_jobs
+	fi
+
+	cd "${S}" || die "Can't enter source folder."
+	newicon ${PN}_icon.png ${PN}-2.6.png
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_qt4 ]] ; then
+		fperms +x /usr/bin/avidemux3_qt4
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_qt5 ]] ; then
+		fperms +x /usr/bin/avidemux3_qt5
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_jobs_qt5 ]] ; then
+		fperms +x /usr/bin/avidemux3_jobs_qt5
+	fi
+
+	if use qt4 || use qt5 ; then
+		domenu ${PN}-2.6.desktop
+	fi
+}
diff --git a/media-video/avidemux/avidemux-9999.ebuild b/media-video/avidemux/avidemux-9999.ebuild
index d31c66fd8977..2ad1ffeee1b4 100644
--- a/media-video/avidemux/avidemux-9999.ebuild
+++ b/media-video/avidemux/avidemux-9999.ebuild
@@ -1,48 +1,59 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
+EAPI="6"
 
 PLOCALES="ca cs de el es fr it ja pt_BR ru sr sr@latin tr"
 
-inherit cmake-utils eutils flag-o-matic l10n
-
-SLOT="2.6"
+inherit cmake-utils l10n
 
 DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
 HOMEPAGE="http://fixounet.free.fr/${PN}"
 
 # Multiple licenses because of all the bundled stuff.
 LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
-IUSE="debug opengl nls qt4 sdl vaapi vdpau video_cards_fglrx xv"
-KEYWORDS="~amd64 ~x86"
+SLOT="2.6"
+IUSE="debug opengl nls nvenc qt4 qt5 sdl vaapi vdpau video_cards_fglrx xv"
 
 if [[ ${PV} == *9999* ]] ; then
-	KEYWORDS=""
-	EGIT_REPO_URI="git://gitorious.org/${PN}2-6/${PN}2-6.git https://git.gitorious.org/${PN}2-6/${PN}2-6.git"
+	MY_P="${P}"
+	EGIT_REPO_URI="https://github.com/mean00/avidemux2.git"
 
-	inherit git-2
+	inherit git-r3
 else
 	MY_P="${PN}_${PV}"
 	SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
 fi
 
 DEPEND="
-	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,video_cards_fglrx?,xv?]
+	~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,video_cards_fglrx?,xv?,nvenc?]
 	opengl? ( virtual/opengl:0 )
 	qt4? ( >=dev-qt/qtgui-4.8.3:4 )
+	qt5? ( dev-qt/qtgui:5 )
 	vaapi? ( x11-libs/libva:0 )
+	nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
 	video_cards_fglrx? (
 		|| ( >=x11-drivers/ati-drivers-14.12-r3
 			x11-libs/xvba-video:0 )
 		)"
-RDEPEND="$DEPEND"
-PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt4?]"
+RDEPEND="
+	$DEPEND
+	nls? ( virtual/libintl:0 )
+"
+PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt4?,qt5?]"
 
 S="${WORKDIR}/${MY_P}"
 
 src_prepare() {
-	cmake-utils_src_prepare
+	default
+
+	processes="buildCli:avidemux/cli"
+	use qt4 && processes+=" buildQt4:avidemux/qt4"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake-utils_src_prepare
+	done
 
 	# Fix icon name -> avidemux-2.6.png
 	sed -i -e "/^Icon/ s:${PN}:${PN}-2.6:" ${PN}2.desktop || die "Icon name fix failed."
@@ -50,7 +61,7 @@ src_prepare() {
 	# The desktop file is broken. It uses avidemux2 instead of avidemux3
 	# so it will actually launch avidemux-2.5 if it is installed.
 	sed -i -e "/^Exec/ s:${PN}2:${PN}3:" ${PN}2.desktop || die "Desktop file fix failed."
-	sed -i -re '/^Exec/ s:(avidemux3_)gtk:\1qt4:' ${PN}2.desktop || die "Desktop file fix failed."
+	sed -i -re '/^Exec/ s:(avidemux3_)gtk:\1qt'$(usex qt5 5 4)':' ${PN}2.desktop || die "Desktop file fix failed."
 
 	# Fix QA warnings that complain a trailing ; is missing and Application is deprecated.
 	sed -i -e 's/Application;AudioVideo/AudioVideo;/g' ${PN}2.desktop || die "Desktop file fix failed."
@@ -63,31 +74,6 @@ src_prepare() {
 }
 
 src_configure() {
-	local mycmakeargs="
-		-DAVIDEMUX_SOURCE_DIR='${S}'
-		$(cmake-utils_use nls GETTEXT)
-		$(cmake-utils_use sdl)
-		$(cmake-utils_use vaapi LIBVA)
-		$(cmake-utils_use vdpau)
-		$(cmake-utils_use video_cards_fglrx XVBA)
-		$(cmake-utils_use xv XVIDEO)
-	"
-
-	if use debug ; then
-		mycmakeargs+=" -DVERBOSE=1 -DCMAKE_BUILD_TYPE=Debug -DADM_DEBUG=1"
-	fi
-
-	processes="buildCli:avidemux/cli"
-	use qt4 && processes+=" buildQt4:avidemux/qt4"
-
-	for process in ${processes} ; do
-		local build="${process%%:*}"
-
-		mkdir "${S}"/${build} || die "Can't create build folder."
-		cd "${S}"/${build} || die "Can't enter build folder."
-		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${S}"/${build} cmake-utils_src_configure
-	done
-
 	# Add lax vector typing for PowerPC.
 	if use ppc || use ppc64 ; then
 		append-cflags -flax-vector-conversions
@@ -95,19 +81,42 @@ src_configure() {
 
 	# See bug 432322.
 	use x86 && replace-flags -O0 -O1
+
+	local mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR='${S}'
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+	)
+
+	if use qt5 ; then
+		mycmakeargs+=( -DENABLE_QT5="$(usex qt5)" )
+	fi
+
+	if use debug ; then
+		mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+	fi
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake-utils_src_configure
+	done
 }
 
 src_compile() {
 	for process in ${processes} ; do
-		BUILD_DIR="${S}/${process%%:*}" cmake-utils_src_compile
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_compile
 	done
 }
 
-DOCS=( AUTHORS README )
-
 src_install() {
 	for process in ${processes} ; do
-		BUILD_DIR="${S}/${process%%:*}" cmake-utils_src_install
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake-utils_src_install
 	done
 
 	if [[ -f "${ED}"/usr/bin/avidemux3_cli ]] ; then
@@ -121,8 +130,19 @@ src_install() {
 	cd "${S}" || die "Can't enter source folder."
 	newicon ${PN}_icon.png ${PN}-2.6.png
 
-	if use qt4 ; then
+	if [[ -f "${ED}"/usr/bin/avidemux3_qt4 ]] ; then
 		fperms +x /usr/bin/avidemux3_qt4
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_qt5 ]] ; then
+		fperms +x /usr/bin/avidemux3_qt5
+	fi
+
+	if [[ -f "${ED}"/usr/bin/avidemux3_jobs_qt5 ]] ; then
+		fperms +x /usr/bin/avidemux3_jobs_qt5
+	fi
+
+	if use qt4 || use qt5 ; then
 		domenu ${PN}-2.6.desktop
 	fi
 }
diff --git a/media-video/avidemux/metadata.xml b/media-video/avidemux/metadata.xml
index 00c928c5b60c..ad0bd2cc0b7d 100644
--- a/media-video/avidemux/metadata.xml
+++ b/media-video/avidemux/metadata.xml
@@ -5,6 +5,9 @@
     <email>media-video@gentoo.org</email>
     <name>Gentoo Video project</name>
   </maintainer>
+  <use>
+    <flag name="nvenc">Adds support for NVIDIA Encoder (NVENC) API for hardware accelerated encoding on NVIDIA cards.</flag>
+  </use>
   <upstream>
     <remote-id type="sourceforge">avidemux</remote-id>
   </upstream>