dev-libs/gobject-introspection: Version bump to 1.72.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/dev-libs/gobject-introspection/Manifest b/dev-libs/gobject-introspection/Manifest
index 4dd84dca0b07..e57456138cfd 100644
--- a/dev-libs/gobject-introspection/Manifest
+++ b/dev-libs/gobject-introspection/Manifest
@@ -1,2 +1,3 @@
 DIST gobject-introspection-1.70.0-meson-0.61.patch.bz2 4211 BLAKE2B 0453266900dfdf24da3531d205fe03d8eb5f6e3d76db4b945852453dc46d26a77449f0ddd81bad6df6d8108d8a7369b60a07b7c4f8e0c01811f735da76cf4d56 SHA512 ba5861baaabfe20185d85ccbc02425d1e44c525a5d05c28ee84552c43ab30497bed4e713e6f1b2f9c6508714020b04b5228532e1489e8a732ba99ea61ca950c7
 DIST gobject-introspection-1.70.0.tar.xz 1029372 BLAKE2B a649ea77b2b7ca392202e21a7f4814aafe57afea7fedb39e78f1df1cd97d0437207c3807a51ece6c9e9bce51fdf961ee7438ccd4efd84b45dbdb57ae19a39272 SHA512 216b376ed423f607e36c723dd6b67975dbfb63c253f2d8bd0b3661e3d69f8c8059cf221db8c5260b0262fad1b7d738f3b2e5fbd51fdbc31e40ccb115c209baf0
+DIST gobject-introspection-1.72.0.tar.xz 1040936 BLAKE2B fd7600a927e57d5a076c203a084afe56a738d3a93109055be7bee22a96d6d5b08892300260288e5b83f883e54ca658cb24ef5c862abe435820c963bbf0cf8496 SHA512 b8fba2bd12e93776c55228acf3487bef36ee40b1abdc7f681b827780ac94a8bfa1f59b0c30d60fa5a1fea2f610de78b9e52029f411128067808f17eb6374cdc5
diff --git a/dev-libs/gobject-introspection/gobject-introspection-1.72.0.ebuild b/dev-libs/gobject-introspection/gobject-introspection-1.72.0.ebuild
new file mode 100644
index 000000000000..7f94660fce13
--- /dev/null
+++ b/dev-libs/gobject-introspection/gobject-introspection-1.72.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="xml"
+inherit gnome.org meson python-single-r1 xdg
+
+DESCRIPTION="Introspection system for GObject-based libraries"
+HOMEPAGE="https://wiki.gnome.org/Projects/GObjectIntrospection"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+IUSE="doctool gtk-doc test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+# virtual/pkgconfig needed at runtime, bug #505408
+RDEPEND="
+	>=dev-libs/gobject-introspection-common-${PV}
+	>=dev-libs/glib-2.58.0:2
+	dev-libs/libffi:=
+	doctool? (
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+# Wants real bison, not virtual/yacc
+DEPEND="${RDEPEND}
+	gtk-doc? ( >=dev-util/gtk-doc-1.19
+		app-text/docbook-xml-dtd:4.3
+		app-text/docbook-xml-dtd:4.5
+	)
+	sys-devel/bison
+	sys-devel/flex
+	test? (
+		x11-libs/cairo[glib]
+		$(python_gen_cond_dep '
+			dev-python/mako[${PYTHON_USEDEP}]
+			dev-python/markdown[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature test cairo)
+		$(meson_feature doctool)
+		#-Dglib_src_dir
+		$(meson_use gtk-doc gtk_doc)
+		#-Dcairo_libname
+		-Dpython="${EPYTHON}"
+		#-Dgir_dir_prefix
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/
+	python_optimize "${ED}"/usr/$(get_libdir)/gobject-introspection/giscanner
+
+	# Prevent collision with gobject-introspection-common
+	rm -v "${ED}"/usr/share/aclocal/introspection.m4 \
+		"${ED}"/usr/share/gobject-introspection-1.0/Makefile.introspection || die
+	rmdir "${ED}"/usr/share/aclocal || die
+}