net-libs/gnutls: eapi bump

Package-Manager: Portage-2.3.49, Repoman-2.3.10

2 files changed, 142 insertions, 11 deletions

diff --git a/net-libs/gnutls/gnutls-3.5.19-r1.ebuild b/net-libs/gnutls/gnutls-3.5.19-r1.ebuild
new file mode 100644
index 000000000000..f9231e34b263
--- /dev/null
+++ b/net-libs/gnutls/gnutls-3.5.19-r1.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+SRC_URI="mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz"
+
+LICENSE="GPL-3 LGPL-2.1"
+SLOT="0/30" # libgnutls.so number
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="+cxx dane doc examples guile +idn nls openpgp +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools valgrind zlib"
+
+REQUIRED_USE="
+	test-full? ( guile pkcs11 openpgp openssl idn seccomp tools zlib )"
+
+# NOTICE: sys-devel/autogen is required at runtime as we
+# use system libopts
+RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
+	dev-libs/libunistring:=[${MULTILIB_USEDEP}]
+	>=dev-libs/nettle-3.1:=[gmp,${MULTILIB_USEDEP}]
+	>=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
+	tools? ( sys-devel/autogen )
+	dane? ( >=net-dns/unbound-1.4.20:=[${MULTILIB_USEDEP}] )
+	guile? ( >=dev-scheme/guile-2:=[networking] )
+	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
+	pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+	idn? ( >=net-dns/libidn2-0.16-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	test? (
+		seccomp? ( sys-libs/libseccomp )
+	)"
+BDEPEND=">=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	valgrind? ( dev-util/valgrind )
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
+	test-full? (
+		app-crypt/dieharder
+		app-misc/datefudge
+		dev-libs/softhsm:2[-bindist]
+		net-dialup/ppp
+		net-misc/socat
+	)"
+
+DOCS=(
+	README.md
+	doc/certtool.cfg
+)
+
+HTML_DOCS=()
+
+pkg_setup() {
+	# bug#520818
+	export TZ=UTC
+
+	use doc && HTML_DOCS+=(
+		doc/gnutls.html
+	)
+}
+
+src_prepare() {
+	default
+
+	# force regeneration of autogen-ed files
+	local file
+	for file in $(grep -l AutoGen-ed src/*.c) ; do
+		rm src/$(basename ${file} .c).{c,h} || die
+	done
+
+	# Use sane .so versioning on FreeBSD.
+	elibtoolize
+}
+
+multilib_src_configure() {
+	LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
+
+	# remove magic of library detection
+	# bug#438222
+	local libconf=($("${S}/configure" --help | grep -- '--without-.*-prefix' | sed -e 's/^ *\([^ ]*\) .*/\1/g'))
+
+	# TPM needs to be tested before being enabled
+	libconf+=( --without-tpm )
+
+	# hardware-accell is disabled on OSX because the asm files force
+	#   GNU-stack (as doesn't support that) and when that's removed ld
+	#   complains about duplicate symbols
+	[[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	# Cygwin as does not understand these asm files at all
+	[[ ${CHOST} == *-cygwin* ]] && libconf+=( --disable-hardware-acceleration )
+
+	ECONF_SOURCE=${S} econf \
+		$(multilib_native_enable manpages) \
+		$(multilib_native_use_enable doc gtk-doc) \
+		$(multilib_native_use_enable doc) \
+		$(multilib_native_use_enable guile) \
+		$(multilib_native_use_enable seccomp seccomp-tests) \
+		$(multilib_native_use_enable test tests) \
+		$(multilib_native_use_enable test-full full-test-suite) \
+		$(multilib_native_use_enable tools) \
+		$(multilib_native_use_enable valgrind valgrind-tests) \
+		$(use_enable cxx) \
+		$(use_enable dane libdane) \
+		$(use_enable nls) \
+		$(use_enable openpgp openpgp-authentication) \
+		$(use_enable openssl openssl-compatibility) \
+		$(use_enable sslv2 ssl2-support) \
+		$(use_enable sslv3 ssl3-support) \
+		$(use_enable static-libs static) \
+		$(use_enable tls-heartbeat heartbeat-support) \
+		$(use_with idn libidn2) \
+		$(use_with idn) \
+		$(use_with pkcs11 p11-kit) \
+		$(use_with zlib) \
+		--with-unbound-root-key-file="${EPREFIX}/etc/dnssec/root-anchors.txt" \
+		--without-included-libtasn1 \
+		"${libconf[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+
+	if use examples; then
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}
diff --git a/net-libs/gnutls/gnutls-3.6.3.ebuild b/net-libs/gnutls/gnutls-3.6.3.ebuild
index fd1664469d06..f5e8e131dfae 100644
--- a/net-libs/gnutls/gnutls-3.6.3.ebuild
+++ b/net-libs/gnutls/gnutls-3.6.3.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-inherit libtool ltprune multilib-minimal versionator
+inherit libtool multilib-minimal
 
 DESCRIPTION="A TLS 1.2 and SSL 3.0 implementation for the GNU project"
 HOMEPAGE="http://www.gnutls.org/"
-SRC_URI="mirror://gnupg/gnutls/v$(get_version_component_range 1-2)/${P}.tar.xz"
+SRC_URI="mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz"
 
 LICENSE="GPL-3 LGPL-2.1"
 SLOT="0/30" # libgnutls.so number
@@ -25,20 +25,19 @@ RDEPEND=">=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
 	>=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
 	tools? ( sys-devel/autogen )
 	dane? ( >=net-dns/unbound-1.4.20:=[${MULTILIB_USEDEP}] )
-	guile? ( >=dev-scheme/guile-1.8:=[networking] )
+	guile? ( >=dev-scheme/guile-2:=[networking] )
 	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
 	pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
 	idn? ( >=net-dns/libidn2-0.16-r1[${MULTILIB_USEDEP}] )"
 DEPEND="${RDEPEND}
-	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
-	doc? ( dev-util/gtk-doc )
-	nls? ( sys-devel/gettext )
-	valgrind? ( dev-util/valgrind )
 	test? (
 		seccomp? ( sys-libs/libseccomp )
-	)
+	)"
+BDEPEND=">=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	valgrind? ( dev-util/valgrind )
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )
 	test-full? (
-		guile? ( >=dev-scheme/guile-2 )
 		app-crypt/dieharder
 		>=app-misc/datefudge-1.22
 		dev-libs/softhsm:2[-bindist]
@@ -120,7 +119,7 @@ multilib_src_configure() {
 
 multilib_src_install_all() {
 	einstalldocs
-	prune_libtool_files --all
+	find "${D}" -name '*.la' -delete || die
 
 	if use examples; then
 		docinto examples