dev-python/statsmodels: add 0.13.5

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/dev-python/statsmodels/Manifest b/dev-python/statsmodels/Manifest
index 541073544dbf..3cb3d897e5da 100644
--- a/dev-python/statsmodels/Manifest
+++ b/dev-python/statsmodels/Manifest
@@ -1 +1,2 @@
 DIST statsmodels-0.13.2.tar.gz 17874260 BLAKE2B 93f7a308217ba938b3cd2e11d75e8f5ad19e2d4e6ab2abbea702143129bb53e7b9be54864375dbfec805624538bc73850357eb944d6c9a4c1252cc8a7606b904 SHA512 79d8dd63f667d4019e462d93e007a5ef8e11972fe35fb4d657931d6d68f3e35d29978a865682133db12fd6742f3362c2d77dfb5735c82ae454570388dd84d59a
+DIST statsmodels-0.13.5.tar.gz 18364957 BLAKE2B 8357416b015b152612aca88a9ff42b81db4d97f61b1c255bc2baf8978440cd43fa1a5301d1c60e92b3a634008c5c001c00770685864d296587ff75e37d29ff4f SHA512 9aeeea80c69f52459140179523a0155429834b2951325c9781b28f8c4cbbd0593ff1867e2212078f2b898e4da953689c2fe78183d3c7959caa874e9d758b4ea4
diff --git a/dev-python/statsmodels/statsmodels-0.13.5.ebuild b/dev-python/statsmodels/statsmodels-0.13.5.ebuild
new file mode 100644
index 000000000000..5caea8067c6e
--- /dev/null
+++ b/dev-python/statsmodels/statsmodels-0.13.5.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="Statistical computations and models for use with SciPy"
+HOMEPAGE="https://www.statsmodels.org/stable/index.html"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+DEPEND="
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.3[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.25[${PYTHON_USEDEP}]
+	>=dev-python/patsy-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.3[${PYTHON_USEDEP}]
+"
+BDEPEND="${DEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ipykernel' \
+	'dev-python/jupyter_client' \
+	'dev-python/matplotlib' \
+	'dev-python/nbconvert' \
+	'dev-python/numpydoc'
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	export VARTEXFONTS="${T}"/fonts
+	export MPLCONFIGDIR="${T}"
+	printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x MKL_NUM_THREADS=1
+	local -x OMP_NUM_THREADS=1
+	local EPYTEST_DESELECT=(
+		# note that test path should be without "statsmodels/" prefix
+		imputation/tests/test_mice.py::TestMICE::test_combine
+		stats/tests/test_mediation.py::test_mixedlm
+		"stats/tests/test_corrpsd.py::test_corrpsd_threshold[0]"
+	)
+
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest ${PN} -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+	rm -r ${PN}/.pytest_cache || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Plotting functionality" "dev-python/matplotlib"
+}