dev-lang/swi-prolog: bump development version

Signed-off-by: Keri Harris <keri@gentoo.org>
Package-Manager: Portage-2.3.76, Repoman-2.3.11

2 files changed, 107 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index f776c668a9a1..a3726ce30718 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -2,3 +2,4 @@ DIST swipl-8.0.3.tar.gz 10418553 BLAKE2B d7d381a3070384164f9788060e1c431cc4658dd
 DIST swipl-8.1.17.tar.gz 10858037 BLAKE2B 69d6528e250dfd780c17bd87c2d79f2923a4ed413d44a5b1f77ca28c2077d8000dc991058fe47a7aaaa6310cf015049980463005d53294a71ba610e43b67b0dd SHA512 42a5a529e1ed935501e87cab28ab5b6d3a18283027bb801a7e3d66d41342fe6ee74de70fe9e8a341f360ab145d0a2e49d8937cb661cfec52f9105c4cf06dc735
 DIST swipl-8.1.18.tar.gz 10865862 BLAKE2B 9728593b9ce890fdb8b4bda8667dbfa9323707d86e0491e62ca82098c62d797da3cdc0180aba0509393532f2b095d1626a0b465955036de80b4fff4dbb62cba6 SHA512 c6b29b57e42e464f03e328fcc272c04db7772b45e62a26fec14f7fe2b9d3c494eeb4c090237b942e38f666dea6fc92e1d00dacba83f6ea74d6dd53923fd23816
 DIST swipl-8.1.19.tar.gz 10865698 BLAKE2B 08da8b7d93a313f621f9bb6abcc509ab6997b673f89483356f6a90f80fd7053acfac611bfaaa2925b3c0d51d7216ea7a1fcbd52dc202961e5a157eb7d0cf0907 SHA512 6094ef47e6c30b5d15f01c8f8c52b125cd04153b9949b6c0a19f4b2e57cd2604377b6b905dec6fa34fd6c6baec1d74d0463c24dfe407fb25643e7e89515b3296
+DIST swipl-8.1.20.tar.gz 10866943 BLAKE2B 57efd2dcd7a60589a5f8073703c121c0bcdc988e5da1a638ec542c18b342d51ef6a26ddc2cadc4fd5d79de37134492b9cf447cb0229faf4366f190169c689592 SHA512 c05b57977d9204916dc18cfcc387971f0dcef74d4b5b0cdfd1d134d57faefd81255b668a97d1d09952ea2d0dcadee0997e84305d49d0252549f6f4d57bf84d4e
diff --git a/dev-lang/swi-prolog/swi-prolog-8.1.20.ebuild b/dev-lang/swi-prolog/swi-prolog-8.1.20.ebuild
new file mode 100644
index 000000000000..67d5ec674d94
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.1.20.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	EPATCH_FORCE=yes
+	EPATCH_SUFFIX=patch
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		epatch "${WORKDIR}"/${PV}
+	fi
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+
+	eapply_user
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile \
+		XDG_CONFIG_DIRS="${HOME}" \
+		XDG_DATA_DIRS="${HOME}"
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}