dev-python/tox: Bump to 4.1.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 92145ebc4ca9..6bdb6615b0a8 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -2,3 +2,4 @@ DIST tox-3.27.1.gh.tar.gz 309006 BLAKE2B fa8aaa9cd5b03e54c166bb6b748290420b91498
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.0.19.gh.tar.gz 284319 BLAKE2B f0ed3d300e0fadfaa5725589cea91511ed0c37937dc3761b203cfd1f0a5cf4033b6006e693521c932d3af64feb150951c046f5853a8b9bb9e37dcf3c5db4de95 SHA512 27d01b96acf4f7650b5a4a3ad80293ea884ee6791ff2e734cb64c94551943af1fb91804944f7ae82937fe4172522c0d5e4f24e84d35012d11657adc49702fc88
 DIST tox-4.1.1.gh.tar.gz 285048 BLAKE2B 78f810889102328a9b1e56d86b2f5d833311a5148fe9eca0f2076892d4ef15c6eee8fdf58c5390a273842cd3f0c50731fc82f10a54a025b6802526711513453b SHA512 7367a2ac9d2233d96affff7cfd357fad516661834db31aee740d77983977ad6136a58c2979eaafbc504844f6ec5bbeeed9b5bd67ba53f2b7d24cf5d83e59d42b
+DIST tox-4.1.2.gh.tar.gz 286306 BLAKE2B 67e52bf01c383e255b22c5c71eecf01d4a041cf4c4399df60451c74acd79bbd1b30f787bcf4f10896804ca1b0cc8b02f6ff4d5e0b7e7ac64284da33f09c95bc9 SHA512 7ff44624c26d609c33dce2cec5bd177caf70b8628f64c48f1fae5130001c508b82079ea4f2487cf8d10b371d0b95cc998c21c47a5080e964db40a3ebafe01a93
diff --git a/dev-python/tox/tox-4.1.2.ebuild b/dev-python/tox/tox-4.1.2.ebuild
new file mode 100644
index 000000000000..f92b0ec6e7c9
--- /dev/null
+++ b/dev-python/tox/tox-4.1.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
+	if [[ ${EPYTHON} == pypy3 ]]; then
+		EPYTEST_DESELECT+=(
+			'tests/tox_env/python/test_python_api.py::test_list_installed_deps[True]'
+		)
+	fi
+
+	epytest
+}