gnome-extra/gnome-software: Version bump to 43.5

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29914
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 6bbea4fe8bbe..ce41cc5fff3b 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
 DIST gnome-software-43.4.tar.xz 2367068 BLAKE2B 9da461876c275a68f75dc5cab15dab1620b084f85115f0695f084f4f85469ede67168feca2123c3303170fbefc00eee59097cca66441c3e01ab3d569fea2c4ec SHA512 3e4c8d29569238ffa116beb8e711f05172572b9b31de7d6f5ff1e26465c9f5be97e465f44ea2f6889e1a6c2b626a2de13b99d2e348a4ef150dca3d56c84ab5cd
+DIST gnome-software-43.5.tar.xz 2366940 BLAKE2B 0f8a371586ffccbf6cf1b58522417a343e70722ad49870eafa09d514d1f0b236100eab092a1d05bf87320c87e5e7a196db945c2d22feebb634a5a156e6f8d82c SHA512 c3d0b05122f5444b1db00719b99f80771ac2ee25ac3caea053bdc734e9faa9730263d20408d4bd87430141392613504b8dff59917eb6a97765302f04ff4306d0
diff --git a/gnome-extra/gnome-software/gnome-software-43.5.ebuild b/gnome-extra/gnome-software/gnome-software-43.5.ebuild
new file mode 100644
index 000000000000..b8cd7539d16d
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-43.5.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software https://gitlab.gnome.org/GNOME/gnome-software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc sysprof udev test"
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	>=gui-libs/gtk-4.6:4
+	>=dev-libs/glib-2.70.0:2
+	>=dev-libs/json-glib-1.6.0
+	>=net-libs/libsoup-3.0:3.0
+	>=gui-libs/libadwaita-1.0.1:1
+	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	sys-auth/polkit
+	firmware? ( >=sys-apps/fwupd-1.5.6 )
+	flatpak? (
+		>=sys-apps/flatpak-1.14.0-r1
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/libglib-testing )
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		-Dpackagekit=false
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dwebapps=true
+		-Dhardcoded_foss_webapps=true
+		-Dhardcoded_proprietary_webapps=true
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_curated=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+		-Dprofile=''
+		-Dsoup2=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}