dev-util/diffoscope: add 260

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index b96389d92a79..b2ddcd8cf753 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -2,3 +2,4 @@ DIST diffoscope-247.tar.bz2 3091118 BLAKE2B cb41b98d439c123b5ee5f458d635f08afebd
 DIST diffoscope-257.tar.bz2 3112404 BLAKE2B cdd7901bdb7cfddb77d165d0084bfc4d9ad1c053bbaee67939acef4cbc0ecb81c2c7443fb7c37bc02b3884433e473dd5cf2afaad28b8535fab70b628df3561e4 SHA512 236ff8fc7e74db2201dfbc0757e6c87aa769c69805319a4ad95faec82f1b0d842a54aaf1c0a0f8f7d74d59c078a696714d92a940d1847530288f95be66dd3dc2
 DIST diffoscope-258.tar.bz2 3111795 BLAKE2B 115db345f5ff4b79045a6297511c9487d7544b80f41161d7b7d6fc6711bce2869603ca6d044c7fbc00b987415cfbc8b359ecbf7a2bdf2061ff2d79e37b903fba SHA512 962920b3493f1f0c99ff109f94f723be60cb2941320118b344aefef21eacccb41f42c429bf7a08a67ce17e6624bac8d509548f14948a357b9ea568a16d0e4213
 DIST diffoscope-259.tar.bz2 3113323 BLAKE2B 58b3bbed61d56ee3782b9d6ff146d2bbfdde1be4cdfba36d2d173a795206bf64a74dbece9e90f0b30ea025d5e353b6820bb4047e767875bb099ec9f659e7b5bd SHA512 32e98806430e353107d4426176c84e17a1d7b2c03a1bdcd3093e67d3b3302800402d26189c1e24cbfdaf28182041c4df857335b608c9ff721408076057f9557c
+DIST diffoscope-260.tar.bz2 3116714 BLAKE2B 72fa7e60f734c82079417404f2850809835d770dbdf1472958daaf0a0b8a0f2e60162ddb0ff56ae711c04984d0680da526238e9e8f34014858b38e83dcc9c8dd SHA512 e33758c9ac28f1b390ce06b0effacc922577faa6f12d5fe89152e9b0223271be7003a03540827d92081be7922705ce09c63bd517e509e4a73beb3415743eef87
diff --git a/dev-util/diffoscope/diffoscope-260.ebuild b/dev-util/diffoscope/diffoscope-260.ebuild
new file mode 100644
index 000000000000..7db31ced97d2
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-260.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+# We could use pypi, but upstream provide distribution tarballs, so let's use those.
+# TODO: verify-sig
+SRC_URI="https://diffoscope.org/archive/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	|| (
+		dev-python/python-magic[${PYTHON_USEDEP}]
+		sys-apps/file[python,${PYTHON_USEDEP}]
+	)
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-alternatives/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/pypdf[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( virtual/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="
+	test? (
+		app-arch/p7zip
+		app-text/docx2txt
+		app-text/html2text
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+	tests/comparators/test_gif.py::test_has_visuals
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+
+	# Fails on ZFS
+	tests/test_main.py::test_non_unicode_filename
+
+	# Fails on (unreleased) LLVM 16 with minor difference
+	#tests/comparators/test_macho.py::test_llvm_diff
+	#tests/comparators/test_elf.py::test_libmix_differences
+)
+
+distutils_enable_tests pytest