net-misc/remmina: bump to 1.3.6

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 96 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 8dca30380295..e2f81bcbd347 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,5 +1,6 @@
 DIST Remmina-v1.2.31.3.tar.gz 1248295 BLAKE2B da748ceea5aa50702b060075c8e5c4aefe11ca1ebbc301b2951df76208da5998746631ef4c57f5692678e948839a8869a183b777f7046d416a55e5ac5b0d76d1 SHA512 f95c4dcebd833b590fbf0b418854bae66541743bc77cda4b0b97e1e49b158927fa859907619fd532b0660fc30eee80be472e02c38a2afe33e477c4a903a99e28
 DIST Remmina-v1.3.3.tar.gz 1362239 BLAKE2B 8ae5b72293ffe2f627a46aa9354256d84d318819b0d5c236f4d5628764eaa9e3a3d07f3130ae04ee271cbc6ac207ccfaf495533b3fa59ee184d3da19c8738bc8 SHA512 72d0303f922619c3842880365bb68b967eb2134fef7187d0fd83aeec2b50fb499573849f853d509216608eefc02db7ced91cfc65f89154b51d0657e42bd0d637
 DIST Remmina-v1.3.4.tar.gz 1365473 BLAKE2B f71a9c0a0fa9eafa547abf192972da39f0cfe1ca3745a87783d6a9ec5bab0674d93df8815b589b25659990bb345748f8f464f401c7efb934e8e71b207b0dab67 SHA512 212ebc6e08c694861522a05feb51e4efa012ef3361debf079384c07e4354370f6cf7d2880ff442bbe03782421bac7f33343d8049207073d90925d1c894d30e7a
+DIST Remmina-v1.3.6.tar.gz 1538166 BLAKE2B f3fc60df2a1a31bd5aae7d8de2d85cd579fa4cc35a0351fbce80433e21583b67cfc81665307d02fbd4863f6a55695be81f9c4d07423d6c8122d84dd625b69c3b SHA512 ce16379aa163467d05018c900d0dc7c2a7d73c1c22dd06a9a3092efa7675fda505bfa31b20131b9a3a10c74788377db17961c0bc9e59c47b1c7a15bf347f3bab
 DIST remmina-1.2.0_rc24.tar.gz 1052140 BLAKE2B 57b3d2ed8a765f98f1ffd3c79df076d07e00329bf95dfddb9094d8bc62838b0f6742b404b4deef0a037bd88259751799e1842fb97313337e11b8f0faed8ad302 SHA512 aab421c580e434ca673be063f3662f1d9128cc83aaee6f9bc6acf6996af0379af6fb99cc63273941c40c6b989653b972de6c43b575ca06bf56ec7c266590c17e
 DIST remmina-1.3.5_p20190731.tar.gz 1475593 BLAKE2B 0a2ddb9c45474e65de9a5be28155ad45f06779170dc360f415ed7ce96fd8595d730eb5f89f756075f89ba5e8e124962fdd07f85d4ac90157eb1e0fae99169fbf SHA512 8b25dae17e13812184481d0640f44a253f0b66260e5e41b06d4e65e9d4dd673d0a17fab2453c9a29ba4691d53ac6e49cb35160931c546a7c68bc483e11eab987
diff --git a/net-misc/remmina/remmina-1.3.6.ebuild b/net-misc/remmina/remmina-1.3.6.ebuild
new file mode 100644
index 000000000000..ca7ab2e53a71
--- /dev/null
+++ b/net-misc/remmina/remmina-1.3.6.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ayatana crypt examples gnome-keyring kwallet libressl nls spice ssh rdp telepathy vnc webkit zeroconf"
+
+CDEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	ayatana? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4 )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( net-dns/avahi[gtk3] )
+"
+DEPEND="${CDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="${CDEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex ayatana)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+	)
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}