net-p2p/qbittorrent: almost completely rewritten ebuild

  * EAPI 6
  * switch to qmake-utils.eclass
  * remove all python handling: it's a runtime-only, optional dep
  * drop USE=qt4 as per Qt project policy
  * add missing [ssl] USE dependency
  * use system qjson when building with qt4
  * drop obsolete boost workaround, now integrated upstream
  * use econf
  * install systemd unit file

Package-Manager: portage-2.2.28

2 files changed, 118 insertions, 41 deletions

diff --git a/net-p2p/qbittorrent/qbittorrent-3.3.4-r1.ebuild b/net-p2p/qbittorrent/qbittorrent-3.3.4-r1.ebuild
new file mode 100644
index 000000000000..c98d0ca8a65f
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-3.3.4-r1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit qmake-utils
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+	MY_P=${P/_}
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+	S=${WORKDIR}/${MY_P}
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug +qt5 webui +X"
+REQUIRED_USE="
+	dbus? ( X )
+"
+
+RDEPEND="
+	dev-libs/boost:=
+	>=net-libs/rb_libtorrent-1.0.6
+	sys-libs/zlib
+	!qt5? (
+		>=dev-libs/qjson-0.8.1[qt4(+)]
+		dev-qt/qtcore:4[ssl]
+		>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt4,X?]
+		dbus? ( dev-qt/qtdbus:4 )
+		X? ( dev-qt/qtgui:4 )
+	)
+	qt5? (
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5[ssl]
+		>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5,X?]
+		dev-qt/qtxml:5
+		dbus? ( dev-qt/qtdbus:5 )
+		X? (
+			dev-qt/qtgui:5
+			dev-qt/qtwidgets:5
+		)
+	)
+"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+	virtual/pkgconfig
+"
+
+DOCS=(AUTHORS Changelog CONTRIBUTING.md README.md TODO)
+
+src_configure() {
+	econf \
+		--with-qjson=system \
+		--with-qtsingleapplication=system \
+		$(use_enable dbus qt-dbus) \
+		$(use_enable debug) \
+		$(use_enable webui) \
+		$(use_enable X gui) \
+		$(use_enable !X systemd) \
+		$(use_with !qt5 qt4)
+
+	if use qt5; then
+		eqmake5
+	else
+		eqmake4
+	fi
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
diff --git a/net-p2p/qbittorrent/qbittorrent-9999.ebuild b/net-p2p/qbittorrent/qbittorrent-9999.ebuild
index 786574f54582..c98d0ca8a65f 100644
--- a/net-p2p/qbittorrent/qbittorrent-9999.ebuild
+++ b/net-p2p/qbittorrent/qbittorrent-9999.ebuild
@@ -2,84 +2,80 @@
 # Distributed under the terms of the GNU General Public License v2
 # $Id$
 
-EAPI=5
-PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+EAPI=6
 
-inherit eutils python-r1 qt4-r2 flag-o-matic
+inherit qmake-utils
 
 DESCRIPTION="BitTorrent client in C++ and Qt"
 HOMEPAGE="http://www.qbittorrent.org/"
 
-MY_P=${P/_}
-if [[ ${PV} == *9999* ]]; then
+if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
 else
+	MY_P=${P/_}
 	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
 	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+	S=${WORKDIR}/${MY_P}
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="+dbus debug qt4 +qt5 webui +X"
+IUSE="+dbus debug +qt5 webui +X"
 REQUIRED_USE="
-	^^ ( qt4 qt5 )
 	dbus? ( X )
 "
 
-CDEPEND="
+RDEPEND="
 	dev-libs/boost:=
-	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt4?,qt5?,X?]
 	>=net-libs/rb_libtorrent-1.0.6
 	sys-libs/zlib
-	qt4? (
-		dev-qt/qtcore:4
+	!qt5? (
+		>=dev-libs/qjson-0.8.1[qt4(+)]
+		dev-qt/qtcore:4[ssl]
+		>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt4,X?]
 		dbus? ( dev-qt/qtdbus:4 )
 		X? ( dev-qt/qtgui:4 )
 	)
 	qt5? (
 		dev-qt/qtconcurrent:5
 		dev-qt/qtcore:5
-		dev-qt/qtnetwork:5
+		dev-qt/qtnetwork:5[ssl]
+		>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5,X?]
 		dev-qt/qtxml:5
 		dbus? ( dev-qt/qtdbus:5 )
-		X? ( dev-qt/qtgui:5
-			dev-qt/qtwidgets:5 )
+		X? (
+			dev-qt/qtgui:5
+			dev-qt/qtwidgets:5
+		)
 	)
 "
-DEPEND="${CDEPEND}
+DEPEND="${RDEPEND}
 	qt5? ( dev-qt/linguist-tools:5 )
 	virtual/pkgconfig
 "
-RDEPEND="${CDEPEND}
-	${PYTHON_DEPS}"
 
-S=${WORKDIR}/${MY_P}
-DOCS=(AUTHORS Changelog README.md TODO)
-
-src_prepare() {
-	epatch_user
-	qt4-r2_src_prepare
-}
+DOCS=(AUTHORS Changelog CONTRIBUTING.md README.md TODO)
 
 src_configure() {
-	# See bug 569062
-	append-cppflags "-DBOOST_NO_CXX11_REF_QUALIFIERS"
+	econf \
+		--with-qjson=system \
+		--with-qtsingleapplication=system \
+		$(use_enable dbus qt-dbus) \
+		$(use_enable debug) \
+		$(use_enable webui) \
+		$(use_enable X gui) \
+		$(use_enable !X systemd) \
+		$(use_with !qt5 qt4)
 
-	# Custom configure script, econf fails
-	local myconf=(
-		./configure
-		--prefix="${EPREFIX}/usr"
-		--with-qtsingleapplication=system
-		$(use dbus  || echo --disable-qt-dbus)
-		$(use debug && echo --enable-debug)
-		$(use qt4   && echo --with-qt4)
-		$(use webui || echo --disable-webui)
-		$(use X     || echo --disable-gui)
-	)
+	if use qt5; then
+		eqmake5
+	else
+		eqmake4
+	fi
+}
 
-	echo "${myconf[@]}"
-	"${myconf[@]}" || die "configure failed"
-	use qt4 && eqmake4
-	use qt5 && eqmake5
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
 }