gnome-extra/cinnamon-settings-daemon: 4.6.4 version bump

Switch to EAPI=7. Drop upstreamed patches.

Bug: https://bugs.gentoo.org/733544
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 113 insertions, 0 deletions

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index fe071f64de05..1b1c7374faa8 100644
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-settings-daemon-4.4.0.tar.gz 665615 BLAKE2B ef0666864a4735ff32d57a584004176c74d0f0ad4b077d3439e135c1d24c8d0606221a1b1693a0189972b462055478680b03917a6acfcdfdc80649f7ee0fc224 SHA512 dc4b0c570b345577bd20e85b44f4c99c3e3c88a2c2aea7c928e1fae931dc4dc07c6dd64c5917661434d35e3ae606c8189c3f77e0658925b5cc6ba2dc1885cb81
+DIST cinnamon-settings-daemon-4.6.4.tar.gz 668339 BLAKE2B 80e14d29a74004c1778e90d39c6ca892d3eee778134e43b8ea77cfec8cbad4f5ac21609cfbb9cdaab0b4d35b42e897223a5b9cdfd43de49d8112b8bc6fc45914 SHA512 77ddb637fd93fdfd59fb27c5a10082259fd99b4753ff36b3473db12f2fe0d19ee89d44c9e72f1ce9eab3f228c5fef418ce774dd78746d77b959ad9d8f93c1208
diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.6.4.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.6.4.ebuild
new file mode 100644
index 000000000000..f0c387f938cd
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-4.6.4.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools eutils gnome2-utils virtualx xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd"
+RESTRICT="test"
+
+# udev is non-optional since lots of plugins, not just gudev, pull it in
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	dev-libs/libgudev:=
+	>=gnome-base/libgnomekbd-3.6
+	>=gnome-extra/cinnamon-desktop-4.6:0=
+	media-libs/fontconfig
+	>=media-libs/lcms-2.2:2
+	media-libs/libcanberra:0=[gtk3]
+	>=sys-apps/dbus-1.1.2
+	>=sys-auth/polkit-0.97
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.9.10:3
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	>=x11-libs/libxklavier-5.0
+	>=sys-power/upower-0.9.11
+
+	colord? ( >=x11-misc/colord-0.1.27:= )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=gnome-base/librsvg-2.36.2
+		x11-drivers/xf86-input-wacom
+		x11-libs/libXtst )
+	smartcard? ( >=dev-libs/nss-3.11.2 )
+	systemd? ( sys-apps/systemd:0= )
+	!systemd? ( sys-auth/elogind:0= )
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=dev-util/intltool-0.37.1
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Make account-services optional
+	"${FILESDIR}"/${PN}-3.8.0-accountservice.patch
+)
+
+src_prepare() {
+	xdg_src_prepare
+	eautoreconf
+	gnome2_disable_deprecation_warning
+
+	# Disable broken test
+	sed -e '/g_test_add_func ("\/color\/edid/d' \
+		-i plugins/color/gcm-self-test.c || die
+}
+
+src_configure() {
+	# no point in disabling gudev since other plugins pull it in
+	econf \
+		--disable-maintainer-mode \
+		--disable-schemas-compile \
+		--enable-compile-warnings=minimum \
+		--disable-static \
+		--enable-gudev \
+		--enable-polkit \
+		--enable-logind \
+		--disable-accountservice \
+		$(use_enable colord color) \
+		$(use_enable cups) \
+		$(use_enable smartcard smartcard-support) \
+		$(use_enable input_devices_wacom wacom)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+	dodoc MAINTAINERS
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}