dev-python/flake8: allow mccabe-0.7, enable py3.11

Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 60 insertions, 0 deletions

diff --git a/dev-python/flake8/files/flake8-4.0.1-upgrade-mccabe.patch b/dev-python/flake8/files/flake8-4.0.1-upgrade-mccabe.patch
new file mode 100644
index 000000000000..5dab4af913fe
--- /dev/null
+++ b/dev-python/flake8/files/flake8-4.0.1-upgrade-mccabe.patch
@@ -0,0 +1,13 @@
+diff --git a/setup.cfg b/setup.cfg
+index 9cbc9b3..732d6a2 100644
+--- a/setup.cfg
++++ b/setup.cfg
+@@ -35,7 +35,7 @@ packages = find:
+ package_dir = 
+ 	=src
+ install_requires = 
+-	mccabe>=0.6.0,<0.7.0
++	mccabe>=0.7.0,<0.8.0
+ 	pycodestyle>=2.8.0,<2.9.0
+ 	pyflakes>=2.4.0,<2.5.0
+ 	importlib-metadata<4.3;python_version<"3.8"
diff --git a/dev-python/flake8/flake8-4.0.1-r2.ebuild b/dev-python/flake8/flake8-4.0.1-r2.ebuild
new file mode 100644
index 000000000000..ffca3f6b10e0
--- /dev/null
+++ b/dev-python/flake8/flake8-4.0.1-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around PyFlakes, pep8 & mccabe"
+HOMEPAGE="https://gitlab.com/pycqa/flake8 https://pypi.org/project/flake8/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+# requires.txt inc. mccabe however that creates a circular dep
+RDEPEND="
+	>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+"
+PDEPEND="
+	>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.8.0[${PYTHON_USEDEP}]
+
+"
+BDEPEND="${RDEPEND}
+	test? (
+		${PDEPEND}
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-upgrade-mccabe.patch"
+)
+
+distutils_enable_sphinx docs/source dev-python/sphinx-prompt dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove version-limited dep
+	sed -i -e '/importlib-metadata/d' setup.cfg || die
+	distutils-r1_src_prepare
+}