dev-python/sphinx: Bump to 6.1.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 129 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index f56da0e60ea4..935659551e94 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -3,3 +3,4 @@ DIST sphinx-5.3.0.gh.tar.gz 6873479 BLAKE2B c57ede5e3d83447c6152d050d45df73bced6
 DIST sphinx-6.0.0.gh.tar.gz 6713685 BLAKE2B b2e333efdbbd319c82203a0ee731ae8b0bc8a848b92773bdaa93b52c3841ab3802f68f698155b8ce4f65af93fdbe741c3e37775defde6111ee6ad5db89f968d8 SHA512 6efcbe57170cacec6f3c7f11f09094d096dc2afb7e0470c7cbdb9ea209dcbb782a6227a32de41974258555fa01986406a6564587f6b414594c452dcc6b8a06fc
 DIST sphinx-6.1.1.gh.tar.gz 6719767 BLAKE2B 91951c896c9feceee5877f98cd6d9afd0868bf6fd0c7372289eff2511ffb3ac845a29a43442c1cc8a9d14be3b242695d6666289b68a3fd41b5fdcbdf87c88145 SHA512 eaeed485d93d9fca3d8c388112594b2f71bed4b3d14ab2d5728ae4ca43bd444668f8b3633f7d2e11f4b1ec20aa309e8f0f70b500752e9f7dfeafd2999244fb58
 DIST sphinx-6.1.2.gh.tar.gz 6720271 BLAKE2B 2206fdd2e3936dded171ffd3aa0895ee9ea337c1a1cd55735eb880a8cbe36f2454fd545883de46831bd29f0738796c0bedbbfda45e6c132e452a36b028bf5e08 SHA512 ecbfea636bf3095b94a38992856c2279f696b8a34558f99b1a08a984c5ace678d68a9bd3197119205f6af6dbbf995c3b820972b7c83d8c628fa5031e0b545e4c
+DIST sphinx-6.1.3.gh.tar.gz 6720056 BLAKE2B 8d8753a7735df1d2e86dfc1c6347ea6fd550c5a6abd5e4cb2b884e0ec9d9de5179eac241cad98aad3ee09cca26d13f74aecc2eb2f61067eb20beb4a26159ac4d SHA512 b1cdd1ae8e643306cbbf26bd926f0fbd6c76a11098cf35c8088dd12f4c8ac4dbb5a7acc0676608d8268059191756e71741564a72e9786a66eb2282afd0271f27
diff --git a/dev-python/sphinx/sphinx-6.1.3.ebuild b/dev-python/sphinx/sphinx-6.1.3.ebuild
new file mode 100644
index 000000000000..880775676d67
--- /dev/null
+++ b/dev-python/sphinx/sphinx-6.1.3.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.9[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.20[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.18[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.25.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.0[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.5[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.8[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+	!dev-python/namespace-sphinxcontrib
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	"${FILESDIR}/sphinx-4.3.2-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local EPYTEST_DESELECT=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		tests/test_build_linkcheck.py::test_defaults
+		tests/test_build_linkcheck.py::test_defaults_json
+		tests/test_build_linkcheck.py::test_anchors_ignored
+		# TODO
+		tests/test_ext_autodoc_autoclass.py::test_classes
+		tests/test_ext_autodoc_autofunction.py::test_classes
+		tests/test_ext_inheritance_diagram.py::test_import_classes
+		# looks like a bug in lualatex
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-howto]"
+		"tests/test_build_latex.py::test_build_latex_doc[lualatex-manual]"
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc_autoclass.py::test_autodoc_process_bases
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_decendants_of_generic_type
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_automodule.py::test_automodule_inherited_members
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_util_inspect.py::test_isattributedescriptor
+		tests/test_util_typing.py::test_stringify_type_hints_pep_585
+	)
+
+	epytest
+}