app-text/bibletime: remove indirect dependencies

Closes: https://bugs.gentoo.org/861044
Signed-off-by: Marek Szuba <marecki@gentoo.org>

2 files changed, 80 insertions, 0 deletions

diff --git a/app-text/bibletime/bibletime-3.0.3-r3.ebuild b/app-text/bibletime/bibletime-3.0.3-r3.ebuild
new file mode 100644
index 000000000000..7c4cc4b09136
--- /dev/null
+++ b/app-text/bibletime/bibletime-3.0.3-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DESCRIPTION="Qt Bible-study application using the SWORD library"
+HOMEPAGE="https://bibletime.info/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=app-text/sword-1.8.1[curl,icu]
+	dev-cpp/clucene
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebchannel:5
+	dev-qt/qtwebengine:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-qt/qttest:5"
+BDEPEND="dev-qt/linguist-tools:5"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.3-no_indirect_deps.patch
+)
+
+DOCS=( ChangeLog README.md )
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "s:Dictionary;Qt:Dictionary;Office;TextTools;Utility;Qt:" \
+		-i cmake/platforms/linux/bibletime.desktop.cmake || die "fixing .desktop file failed"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_HANDBOOK_HTML=no
+		-DBUILD_HANDBOOK_PDF=no
+		-DBUILD_HOWTO_HTML=no
+		-DBUILD_HOWTO_PDF=no
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/app-text/bibletime/files/bibletime-3.0.3-no_indirect_deps.patch b/app-text/bibletime/files/bibletime-3.0.3-no_indirect_deps.patch
new file mode 100644
index 000000000000..87a129c9d80b
--- /dev/null
+++ b/app-text/bibletime/files/bibletime-3.0.3-no_indirect_deps.patch
@@ -0,0 +1,20 @@
+According to documentation upstream build scripts only look for these
+packages to try and guess whether support for them has been enabled
+in app-text/sword.
+
+--- a/platforms/common/core/core.pro
++++ b/platforms/common/core/core.pro
+@@ -173,13 +173,5 @@
+ # Clucene
+ include(../../common/clucene/clucene.pro)
+ 
+-# CURL
+-# optional
+-curl:include(../../common/curl/curl.pro)
+-
+-# ICU
+-# optional
+-icu:include(../../common/icu/icu.pro)
+-
+ # Sword
+ include(../../common/sword/sword.pro)