app-admin/ansible-molecule: add 5.0.1

With documentation generation disabled for now due to the minor
dependency hell involved.

Bug: https://bugs.gentoo.org/905911
Signed-off-by: Marek Szuba <marecki@gentoo.org>

3 files changed, 82 insertions, 0 deletions

diff --git a/app-admin/ansible-molecule/Manifest b/app-admin/ansible-molecule/Manifest
index 5adffb0b199e..5b9a3a680071 100644
--- a/app-admin/ansible-molecule/Manifest
+++ b/app-admin/ansible-molecule/Manifest
@@ -1 +1,2 @@
 DIST molecule-4.0.4.tar.gz 337260 BLAKE2B 14c493fa8aaa15466ebca19af9e5325ddb824c151d07d800136dcb714a430ea2dc42b38c9ec6e805e29ec3226376a532793d51c5d0544d6d5105510e5365ca8c SHA512 d7c1ceefbf74cbc27a397e7a40d855b23325bbde31a4cd1920961413a7db950e9fc530fec180de877eb37984bac8603033aa5a582e68e7f4c4ac2a10721c6630
+DIST molecule-5.0.1.tar.gz 334911 BLAKE2B c021171996a4e57a3f3cffc1f72396b07c59f0e0c6a4b9277d9ad994655f37aafc920164f6a91f9a533497f24cc780d4ff07a8e40cfea4ce89e6249b8415e438 SHA512 c5d6a112c328932c16c8e126cd6308ad8aecc46a03ab43fef2fd0869e5b93c7216df4c7f7e115ebf8e4b4293968848598e8e02e462b0a9d91307f79c6b0a01bd
diff --git a/app-admin/ansible-molecule/ansible-molecule-5.0.1.ebuild b/app-admin/ansible-molecule/ansible-molecule-5.0.1.ebuild
new file mode 100644
index 000000000000..ac127b363db2
--- /dev/null
+++ b/app-admin/ansible-molecule/ansible-molecule-5.0.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+DOCS_BUILDER="mkdocs"
+# cairosvg and pillow are technically speaking dependencies of the mkdocs-material
+# plugin "social" (Bug #906126).
+# Still missing: dev-python/mkdocstrings[python]
+DOCS_DEPEND="
+	dev-python/pillow
+	>=dev-python/mkdocs-ansible-0.1.4
+	dev-python/mkdocs-autorefs
+	media-gfx/cairosvg
+"
+PYPI_PN="molecule"
+
+inherit distutils-r1 docs optfeature pypi
+
+DESCRIPTION="A toolkit designed to aid in the development and testing of Ansible roles"
+HOMEPAGE="https://pypi.org/project/molecule/ https://github.com/ansible-community/molecule/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="selinux"
+
+RDEPEND="$(python_gen_cond_dep '
+	<dev-python/ansible-compat-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/click-8.0[${PYTHON_USEDEP}]
+	<dev-python/click-9[${PYTHON_USEDEP}]
+	>=dev-python/click-help-colors-0.9[${PYTHON_USEDEP}]
+	>=dev-python/enrich-1.2.7[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.11.3[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.9.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	<dev-python/pluggy-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/rich-9.5.1[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.7.3[${PYTHON_USEDEP}]
+	selinux? ( sys-libs/libselinux[python,${PYTHON_USEDEP}] )
+')"
+BDEPEND="$(python_gen_cond_dep '
+	>=dev-python/setuptools-scm-7.0.0[${PYTHON_USEDEP}]
+	test? (
+		app-admin/ansible-lint[${PYTHON_USEDEP}]
+		app-misc/check-jsonschema[${PYTHON_USEDEP}]
+		>=dev-python/ansi2html-1.6.0[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		<dev-python/pexpect-5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.10.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-plus-0.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-testinfra-7.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1.0[${PYTHON_USEDEP}]
+	)
+')"
+
+# test_role.py doesn't play nicely with FEATURES=usersandbox. As for test_command.py:
+#  - quite a few of these tests use the network;
+#  - test_command_dependency[shell] only works if Molecule has previously been installed;
+#  - tests involving creation of a new scenario fail on ansible-lint errors, even though
+#    a config file is deployed which should skip expected issues.
+EPYTEST_DESELECT=(
+	src/molecule/test/functional/test_command.py
+	src/molecule/test/unit/command/init/test_role.py
+)
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature_header "Some optional packages commonly used in Molecule scenarios:"
+	optfeature "checking playbooks for practices and behaviour that can be improved" app-admin/ansible-lint
+}
diff --git a/profiles/base/package.use.mask b/profiles/base/package.use.mask
index 0af297a70e2b..17e2559ff1c3 100644
--- a/profiles/base/package.use.mask
+++ b/profiles/base/package.use.mask
@@ -6,6 +6,11 @@
 # This file is only for generic masks. For arch-specific masks (i.e.
 # mask everywhere, unmask on arch/*) use arch/base.
 
+# Marek Szuba <marecki@gentoo.org> (2023-05-11)
+# New doc-building system which depends on many packages currently absent
+# from the tree. Work in progress.
+>=app-admin/ansible-molecule-5.0.0 doc
+
 # Joonas Niilola <juippis@gentoo.org> (2023-05-07)
 # Doesn't compile, see #894210.
 dev-libs/log4cxx smtp