dev-python/tempest: Bump to 34.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 76 insertions, 0 deletions

diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 0ad9fde44e11..cb6905a9e090 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1,2 +1,3 @@
 DIST tempest-33.0.0.tar.gz 1126464 BLAKE2B 14bce9e0baf1878fc30cc5026c7849cda5abc0291706c7cd051827ffb1e15670e653a20ba6c0c898e86a7e1bee498d14139f82887606f5587b7775d18f96595f SHA512 1a34bc81a18121e3be05ab1a2b637aa8bfc41a0a8e11824294c78468762fb5f303ebf9607f5e72aed1cc5b130b26e22bf72c0574472a0de4eca083e899ff6eb0
 DIST tempest-34.0.0.tar.gz 1138466 BLAKE2B fb08579592445ad9d7bebff5c828b507ddd4d3db560d3d6548a1f26e3ee942f0fda74082eaeee8bba224f284942a4dcf1cabeab9a35821b1a03d0d9d1d126b45 SHA512 83d23d8e6cf6507eec175733372a4f8a4e95e9cb66cdb0ad716bdd4de211a8ae290ba0f56f6ebd1262ff8769619aa6b9e4cba4bc6e7e3dabf1c702167077a962
+DIST tempest-34.1.0.tar.gz 1139228 BLAKE2B 32fefb49ad5a341d297cf660387e66f69e0f3f81cba5f0530190bf5562c7a391359667390045fd746977020376e426aea351a2f50652d67693946bdb8dcfba18 SHA512 89cb682edb3d99c22e9c654a9e546e649837abf7e0b798d84c16d70bef4527d094dd6bbe1d11b8996412cd7e6f073fd1a3f80e5214d7d3a44965f3b542fa13e5
diff --git a/dev-python/tempest/tempest-34.1.0.ebuild b/dev-python/tempest/tempest-34.1.0.ebuild
new file mode 100644
index 000000000000..9143d3959fb9
--- /dev/null
+++ b/dev-python/tempest/tempest-34.1.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	eunittest -b -s tempest/tests -t .
+}