dev-python/s3transfer: Disable Python < 3.10

Signed-off-by: Michał Górny <mgorny@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-python/s3transfer/s3transfer-0.6.0-r1.ebuild b/dev-python/s3transfer/s3transfer-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..fb661e81e32a
--- /dev/null
+++ b/dev-python/s3transfer/s3transfer-0.6.0-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="An Amazon S3 Transfer Manager"
+HOMEPAGE="
+	https://github.com/boto/s3transfer/
+	https://pypi.org/project/s3transfer/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-1.24.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest tests/{unit,functional}
+}