app-backup/cpdup: update EAPI 6 -> 8

Closes: https://bugs.gentoo.org/507522
Closes: https://bugs.gentoo.org/716100
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 39 insertions, 0 deletions

diff --git a/app-backup/cpdup/cpdup-1.18-r1.ebuild b/app-backup/cpdup/cpdup-1.18-r1.ebuild
new file mode 100644
index 000000000000..5e6eccb3db93
--- /dev/null
+++ b/app-backup/cpdup/cpdup-1.18-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="A comprehensive filesystem mirroring program"
+HOMEPAGE="http://apollo.backplane.com/FreeSrc/"
+SRC_URI="http://apollo.backplane.com/FreeSrc/${P}.tgz"
+S="${WORKDIR}/${PN}"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-libs/libbsd:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-makefile.patch
+	"${FILESDIR}"/${P}-portable.patch
+)
+
+src_prepare() {
+	default
+	rm compat_linux.c || die
+}
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+}
+
+src_install() {
+	dobin cpdup
+	doman cpdup.1
+	dodoc -r scripts
+}