app-backup/duplicity: version bump to 0.7.11

1 files changed, 52 insertions, 0 deletions

diff --git a/app-backup/duplicity/duplicity-0.7.11.ebuild b/app-backup/duplicity/duplicity-0.7.11.ebuild
new file mode 100644
index 000000000000..04a62398c05a
--- /dev/null
+++ b/app-backup/duplicity/duplicity-0.7.11.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 versionator
+
+DESCRIPTION="Secure backup system using gnupg to encrypt data"
+HOMEPAGE="http://www.nongnu.org/duplicity/"
+SRC_URI="https://code.launchpad.net/${PN}/$(get_version_component_range 1-2)-series/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="s3 test"
+
+CDEPEND="
+	net-libs/librsync
+	app-crypt/gnupg
+	dev-python/lockfile
+"
+DEPEND="${CDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	s3? ( dev-python/boto[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	# workaround until failing test is fixed
+	local PATCHES=( "${FILESDIR}"/${PN}-0.6.24-skip-test.patch )
+
+	distutils-r1_python_prepare_all
+
+	sed -i "s/'COPYING',//" setup.py || die
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	einfo "Duplicity has many optional dependencies to support various backends."
+	einfo "Currently it's up to you to install them as necessary."
+}