app-benchmarks/acovea: [QA] Port to EAPI 6

Package-Manager: Portage-2.3.19, Repoman-2.3.6

1 files changed, 47 insertions, 0 deletions

diff --git a/app-benchmarks/acovea/acovea-5.1.1-r2.ebuild b/app-benchmarks/acovea/acovea-5.1.1-r2.ebuild
new file mode 100644
index 000000000000..ed0e2b0232d9
--- /dev/null
+++ b/app-benchmarks/acovea/acovea-5.1.1-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools
+
+DESCRIPTION="Analysis of Compiler Options via Evolutionary Algorithm"
+HOMEPAGE="http://www.coyotegulch.com/products/acovea/"
+SRC_URI="http://www.coyotegulch.com/distfiles/lib${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="static-libs"
+
+RDEPEND="
+	>=dev-libs/libcoyotl-3.1.0:=
+	>=dev-libs/libevocosm-3.3.0:=
+	dev-libs/expat:="
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/lib${P}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-asneeded.patch
+	"${FILESDIR}"/${P}-free-fix.patch
+	"${FILESDIR}"/${P}-gcc44.patch
+	"${FILESDIR}"/${P}-glibc-212.patch
+	"${FILESDIR}"/${P}-underlinking.patch
+	"${FILESDIR}"/${P}-libevocosm.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}