proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 52 insertions, 0 deletions

diff --git a/app-cdr/dvd95/dvd95-1.6_p0.ebuild b/app-cdr/dvd95/dvd95-1.6_p0.ebuild
new file mode 100644
index 000000000000..30fcb5f37776
--- /dev/null
+++ b/app-cdr/dvd95/dvd95-1.6_p0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=2
+inherit eutils autotools
+
+DESCRIPTION="DVD95 is a Gnome application to convert DVD9 to DVD5"
+HOMEPAGE="http://dvd95.sourceforge.net/"
+SRC_URI="mirror://sourceforge/dvd95/${P/_}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_3dnow nls cpu_flags_x86_mmx mpeg cpu_flags_x86_sse cpu_flags_x86_sse2"
+
+RDEPEND=">=gnome-base/libgnomeui-2
+	dev-libs/libxml2
+	media-libs/libdvdread
+	mpeg? ( media-libs/libmpeg2 )
+	media-video/mplayer"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext
+		dev-util/intltool )
+	sys-apps/sed"
+
+S=${WORKDIR}/${P/_}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.3_p2-desktop-entry.patch
+	epatch "${FILESDIR}"/${P}-link-libxml2.patch
+	sed -i -e "s:-O3:${CFLAGS}:" configure.in || die "sed failed"
+	echo "dvd95.glade" >> po/POTFILES.in || die "translation fix failed"
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable nls) \
+		$(use_enable cpu_flags_x86_mmx mmx) \
+		$(use_enable cpu_flags_x86_3dnow 3dnow) \
+		$(use_enable cpu_flags_x86_sse sse) \
+		$(use_enable cpu_flags_x86_sse2 sse2) \
+		$(use_enable mpeg libmpeg2)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog
+}