app-crypt/rhash: Fix missing headers and dash issue

I swear it installed the headers without this line at least some of
the time. Yay for custom build systems.

Closes: https://bugs.gentoo.org/650840
Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 71 insertions, 0 deletions

diff --git a/app-crypt/rhash/rhash-1.3.6-r1.ebuild b/app-crypt/rhash/rhash-1.3.6-r1.ebuild
new file mode 100644
index 000000000000..affa82411479
--- /dev/null
+++ b/app-crypt/rhash/rhash-1.3.6-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs multilib-minimal
+
+DESCRIPTION="Console utility and library for computing and verifying file hash sums"
+HOMEPAGE="http://rhash.anz.ru/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="debug nls openssl static-libs"
+
+RDEPEND="openssl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+S="${WORKDIR}/RHash-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/unquote-cc.patch
+	"${FILESDIR}"/${P}-no_echon.patch
+)
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	set -- \
+		./configure \
+		--cc="$(tc-getCC)" \
+		--ar="$(tc-getAR)" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-ldflags="${LDFLAGS}" \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--sysconfdir="${EPREFIX}"/etc \
+		--disable-openssl-runtime \
+		--disable-static \
+		--enable-lib-shared \
+		$(use_enable debug) \
+		$(use_enable nls gettext) \
+		$(use_enable openssl) \
+		$(use_enable static-libs lib-static)
+
+	echo "${@}"
+	"${@}" || die "configure failed"
+}
+
+# We would add compile-gmo to the build targets but install-gmo always
+# recompiles unconditionally. :(
+
+multilib_src_install() {
+	# -j1 needed due to race condition.
+	emake DESTDIR="${D}" -j1 \
+		  install{,-lib-so-link,-pkg-config} \
+		  $(use nls && echo install-gmo)
+
+	emake DESTDIR="${D}" -j1 \
+		  -C lib${PN} install-headers
+}
+
+multilib_src_test() {
+	emake test
+}