summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSalah Coronya <salah.coronya@gmail.com>2020-11-06 23:44:09 -0600
committerAaron Bauman <bman@gentoo.org>2020-11-13 16:28:42 -0500
commitd7b261cc46c74fd27cd3f253025c0121cc2989c0 (patch)
tree1aaccb65fd9609a4aae44737ac7626435ef64aa5 /app-crypt/trousers/trousers-0.3.15.ebuild
parentgui-apps/gtkgreet: remove Werror build flag (diff)
downloadgentoo-d7b261cc46c74fd27cd3f253025c0121cc2989c0.tar.gz
gentoo-d7b261cc46c74fd27cd3f253025c0121cc2989c0.tar.bz2
gentoo-d7b261cc46c74fd27cd3f253025c0121cc2989c0.zip
app-crypt/trousers: Bump to 0.3.15
Package-Manager: Portage-3.0.8, Repoman-3.0.2 Signed-off-by: Salah Coronya <salah.coronya@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/18162 Signed-off-by: Aaron Bauman <bman@gentoo.org>
Diffstat (limited to 'app-crypt/trousers/trousers-0.3.15.ebuild')
-rw-r--r--app-crypt/trousers/trousers-0.3.15.ebuild65
1 files changed, 65 insertions, 0 deletions
diff --git a/app-crypt/trousers/trousers-0.3.15.ebuild b/app-crypt/trousers/trousers-0.3.15.ebuild
new file mode 100644
index 000000000000..94a40dd74e31
--- /dev/null
+++ b/app-crypt/trousers/trousers-0.3.15.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info readme.gentoo-r1 systemd udev
+
+DESCRIPTION="An open-source TCG Software Stack (TSS) v1.1 implementation"
+HOMEPAGE="http://trousers.sf.net"
+SRC_URI="mirror://sourceforge/trousers/${PN}/${P}.tar.gz"
+
+LICENSE="CPL-1.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~m68k ~ppc ~ppc64 ~s390 ~x86"
+IUSE="doc libressl selinux" # gtk
+
+# gtk support presently does NOT compile.
+# gtk? ( >=x11-libs/gtk+-2 )
+
+DEPEND="acct-group/tss
+ acct-user/tss
+ >=dev-libs/glib-2
+ !libressl? ( >=dev-libs/openssl-0.9.7:0= )
+ libressl? ( dev-libs/libressl:0= )"
+RDEPEND="${DEPEND}
+ selinux? ( sec-policy/selinux-tcsd )"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-0.3.13-nouseradd.patch"
+ "${FILESDIR}/${PN}-0.3.14-Makefile.am-Mark-tddl.a-nodist.patch"
+)
+
+DOCS="AUTHORS ChangeLog NICETOHAVES README TODO"
+
+DOC_CONTENTS="
+ If you have problems starting tcsd, please check permissions and
+ ownership on /dev/tpm* and ~tss/system.data
+"
+
+CONFIG_CHECK="~TCG_TPM"
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ # econf --with-gui=$(usex gtk gtk openssl)
+ econf --with-gui=openssl
+}
+
+src_install() {
+ default
+ find "${D}" -name '*.la' -delete || die
+
+ keepdir /var/lib/tpm
+ use doc && dodoc doc/*
+ newinitd "${FILESDIR}"/tcsd.initd tcsd
+ newconfd "${FILESDIR}"/tcsd.confd tcsd
+ systemd_dounit "${FILESDIR}"/tcsd.service
+ udev_dorules "${FILESDIR}"/61-trousers.rules
+ fowners tss:tss /var/lib/tpm
+ readme.gentoo_create_doc
+}