proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 85 insertions, 0 deletions

diff --git a/app-editors/scite/scite-3.5.5.ebuild b/app-editors/scite/scite-3.5.5.ebuild
new file mode 100644
index 000000000000..f17d015193c2
--- /dev/null
+++ b/app-editors/scite/scite-3.5.5.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit toolchain-funcs eutils
+
+MY_PV=${PV//./}
+DESCRIPTION="A very powerful editor for programmers"
+HOMEPAGE="http://www.scintilla.org/SciTE.html"
+SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"
+
+LICENSE="HPND lua? ( MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="lua"
+
+RDEPEND="dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/gdk-pixbuf
+	x11-libs/pango
+	lua? ( >=dev-lang/lua-5:0= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	>=sys-apps/sed-4"
+
+S="${WORKDIR}/${PN}/gtk"
+
+src_prepare() {
+	cd "${WORKDIR}/scintilla/gtk"
+	sed -i makefile \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
+		-e "s#-Os##" \
+		|| die "error patching makefile"
+
+	cd "${WORKDIR}/scite/gtk"
+	sed -i makefile \
+		-e "s#-rdynamic#-rdynamic ${LDFLAGS}#" \
+		|| die "error patching makefile"
+
+	cd "${S}"
+	sed -i makefile \
+		-e 's#usr/local#usr#g' \
+		-e 's#/gnome/apps/Applications#/applications#' \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
+		-e 's#${D}##' \
+		-e 's#-g root#-g 0#' \
+		-e "s#-Os##" \
+		|| die "error patching makefile"
+}
+
+src_compile() {
+	emake -C ../../scintilla/gtk AR="$(tc-getAR)"
+	if use lua; then
+		emake
+	else
+		emake NO_LUA=1
+	fi
+}
+
+src_install() {
+	dodir /usr/bin
+	dodir /usr/share/{pixmaps,applications}
+
+	emake prefix="${ED}/usr" install
+
+	# we have to keep this because otherwise it'll break upgrading
+	mv "${ED}/usr/bin/SciTE" "${ED}/usr/bin/scite" || die
+	dosym /usr/bin/scite /usr/bin/SciTE
+
+	# replace .desktop file with our own working version
+	rm -f "${ED}/usr/share/applications/SciTE.desktop" || die
+	domenu "${FILESDIR}/scite.desktop"
+
+	doman ../doc/scite.1
+	dodoc ../README
+}