app-emacs/yc: update to EAPI 6

Gentoo-Bug: 621518

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 23 insertions, 25 deletions

diff --git a/app-emacs/yc/yc-4.0.13.ebuild b/app-emacs/yc/yc-4.0.13.ebuild
index f2724d973965..a8179e6426bb 100644
--- a/app-emacs/yc/yc-4.0.13.ebuild
+++ b/app-emacs/yc/yc-4.0.13.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=3
+EAPI="6"
 
 inherit elisp toolchain-funcs
 
@@ -14,42 +14,40 @@ SLOT="0"
 KEYWORDS="alpha ~amd64 ppc x86"
 IUSE=""
 
-DEPEND=""
-RDEPEND=">=app-i18n/canna-3.6"
+RDEPEND="app-i18n/canna"
 
 SITEFILE="50${PN}-gentoo.el"
 
 src_prepare() {
-	sed -e 's:$(CC) -o $(PROGRAM) $(OBJS):$(CC) ${CFLAGS} ${LDFLAGS} -o $(PROGRAM) $(OBJS):' -i Makefile || die
+	sed -i '/$(CC)/s/ -o / $(CFLAGS) $(LDFLAGS) -o /' Makefile
+
+	default
 }
 
 src_compile() {
-	emake CC="$(tc-getCC)" || die
+	emake CC="$(tc-getCC)"
 }
 
 src_install() {
-	elisp-install ${PN} *.el *.elc || die
-	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
-	dobin icanna || die
-	newdoc "${FILESDIR}"/sample.dot.emacs-4 sample.dot.emacs || die
-	dodoc "${FILESDIR}"/sample.hosts.canna || die
+	elisp_src_install
+
+	dobin icanna
+	dodoc "${FILESDIR}"/sample.{dot.emacs,hosts.canna}
 }
 
 pkg_postinst() {
-	elisp-site-regen
-	elog "See the sample.dot.emacs file in /usr/share/doc/${PF}/."
+	elisp_pkg_postinst
+
+	elog "See the sample.dot.emacs in ${EPREFIX}/usr/share/doc/${PF}."
 	elog
-	elog "And If you use unix domain socket for connecting the canna server, "
-	elog "  please confirm that there's *no* following line in your .emacs ."
-	elog "  (setq yc-server-host \"localhost\")"
+	elog "And If you use unix domain socket for connecting the canna server,"
+	elog "please confirm that there's *no* following line in your ~/.emacs:"
+	elog '  (setq yc-server-host "localhost")'
 	elog
-	elog "If you use inet domain socket for connecting the canna server, "
-	elog "  please modify as following in /etc/conf.d/canna."
-	elog "  CANNASERVER_OPTS=\"-inet\""
-	elog "  And create /etc/hosts.canna."
-	elog "  (see the sample.hosts.canna file in /usr/share/doc/${PF}/)"
-}
-
-pkg_postrm() {
-	elisp-site-regen
+	elog "If you use inet domain socket for connecting the canna server,"
+	elog "please modify as following in ${EPREFIX}/etc/conf.d/canna:"
+	elog '  CANNASERVER_OPTS="-inet"'
+	elog
+	elog "And create ${EPREFIX}/etc/hosts.canna."
+	elog "See the sample.hosts.canna in ${EPREFIX}/usr/share/doc/${PF}."
 }