summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorUlrich Müller <ulm@gentoo.org>2020-04-19 15:37:44 +0200
committerUlrich Müller <ulm@gentoo.org>2020-04-19 15:38:44 +0200
commitf290e6b53c2707d45bd6079c373ea99d7a896896 (patch)
tree73d75bd7ab6c49fe8271e6fb7aae2eab33807855 /app-emacs
parentapp-admin/gixy: add Python 3.7 & 3.8 support (diff)
downloadgentoo-f290e6b53c2707d45bd6079c373ea99d7a896896.tar.gz
gentoo-f290e6b53c2707d45bd6079c373ea99d7a896896.tar.bz2
gentoo-f290e6b53c2707d45bd6079c373ea99d7a896896.zip
app-emacs/pymacs: Add python 3.7 and 3.8 support.
Don't remove the version in pymacs-python-command. Build PDF documentation with USE=doc (which was commented out). Closes: https://bugs.gentoo.org/718206 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Ulrich Müller <ulm@gentoo.org>
Diffstat (limited to 'app-emacs')
-rw-r--r--app-emacs/pymacs/pymacs-0.26-r1.ebuild47
1 files changed, 47 insertions, 0 deletions
diff --git a/app-emacs/pymacs/pymacs-0.26-r1.ebuild b/app-emacs/pymacs/pymacs-0.26-r1.ebuild
new file mode 100644
index 00000000000..0ff10a4675c
--- /dev/null
+++ b/app-emacs/pymacs/pymacs-0.26-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit elisp distutils-r1
+
+DESCRIPTION="A tool that allows both-side communication beetween Python and Emacs Lisp"
+HOMEPAGE="https://www.emacswiki.org/emacs/PyMacs"
+SRC_URI="https://github.com/dgentry/${PN^}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc"
+
+BDEPEND="doc? (
+ >=dev-python/docutils-0.7
+ virtual/latex-base
+ )"
+
+S="${WORKDIR}/${P^}"
+DISTUTILS_IN_SOURCE_BUILD=1
+DISTUTILS_USE_SETUPTOOLS="no"
+SITEFILE="50${PN}-gentoo.el"
+
+# called by distutils-r1 for every python implementation
+python_configure() {
+ # pre-process the files but don't run distutils
+ emake PYSETUP=: PYTHON=${EPYTHON}
+}
+
+# called once
+python_compile_all() {
+ elisp_src_compile
+ if use doc; then
+ VARTEXFONTS="${T}"/fonts emake RST2LATEX=rst2latex.py pymacs.pdf
+ fi
+}
+
+python_install_all() {
+ elisp_src_install
+ distutils-r1_python_install_all
+ dodoc pymacs.rst
+ use doc && dodoc pymacs.pdf
+}