app-emulation/containerd: Version bump to 1.1.2

Package-Manager: Portage-2.3.43, Repoman-2.3.10

1 files changed, 55 insertions, 0 deletions

diff --git a/app-emulation/containerd/containerd-1.1.2.ebuild b/app-emulation/containerd/containerd-1.1.2.ebuild
new file mode 100644
index 000000000000..2aebd40c4137
--- /dev/null
+++ b/app-emulation/containerd/containerd-1.1.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN="github.com/containerd/${PN}"
+
+inherit toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	inherit golang-vcs
+else
+	MY_PV="${PV/_rc/-rc.}"
+	EGIT_COMMIT="v${MY_PV}"
+	CONTAINERD_COMMIT="468a545b9edcd5932818eb9de8e72413e616e86e"
+	SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64"
+	inherit golang-vcs-snapshot
+fi
+
+DESCRIPTION="A daemon to control runC"
+HOMEPAGE="https://containerd.tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="apparmor +btrfs +cri hardened +seccomp"
+
+DEPEND="btrfs? ( sys-fs/btrfs-progs )
+	seccomp? ( sys-libs/libseccomp )"
+RDEPEND="|| ( >=app-emulation/docker-runc-1.0.0_rc4
+	>=app-emulation/runc-1.0.0_rc4 )
+	seccomp? ( sys-libs/libseccomp )"
+
+S=${WORKDIR}/${P}/src/${EGO_PN}
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+	if [[ ${PV} != *9999* ]]; then
+		sed -i -e "s/git describe --match.*$/echo ${PV})/"\
+			-e "s/git rev-parse HEAD.*$/echo $CONTAINERD_COMMIT)/"\
+			-e "s/-s -w//" \
+			Makefile || die
+	fi
+}
+
+src_compile() {
+	local options=( $(usex btrfs "" "no_btrfs") $(usex cri "" "no_cri") $(usex seccomp "seccomp" "") $(usex apparmor "apparmor" "") )
+	export GOPATH="${WORKDIR}/${P}" # ${PWD}/vendor
+	LDFLAGS=$(usex hardened '-extldflags -fno-PIC' '') emake BUILDTAGS="${options[@]}"
+}
+
+src_install() {
+	dobin bin/containerd{-shim,-stress,} bin/ctr
+}