app-emulation/crun: new ebuild ( 0.10.6 )

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Dan Molik <dan@danmolik.com>
Tested-by: Dan Molik <dan@danmolik.com>
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/app-emulation/crun/crun-0.10.6.ebuild b/app-emulation/crun/crun-0.10.6.ebuild
new file mode 100644
index 000000000000..b67e905bdb7c
--- /dev/null
+++ b/app-emulation/crun/crun-0.10.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit python-any-r1
+
+DESCRIPTION="A fast and low-memory footprint OCI Container Runtime fully written in C"
+HOMEPAGE="https://github.com/containers/crun"
+SRC_URI="https://github.com/containers/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="bpf +caps doc seccomp systemd static-libs"
+
+DEPEND="
+	dev-libs/yajl
+	sys-libs/libseccomp
+	caps? ( sys-libs/libcap )
+	seccomp? ( sys-libs/libseccomp )
+	systemd? ( sys-apps/systemd:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( dev-go/go-md2man )
+"
+
+DOCS=README.md
+
+src_configure() {
+	econf \
+		$(use_enable bpf) \
+		$(use_enable caps) \
+		$(use_enable seccomp) \
+		$(use_enable systemd) \
+		$(usex static-libs '--enabled-shared  --enabled-static' '--enable-shared --disable-static' '' '')
+}
+
+src_compile() {
+	pushd libocispec || die
+	emake
+	popd || die
+	emake crun
+	if use doc ; then
+		emake crun.1
+	fi
+}
+
+src_install() {
+	pushd libocispec || die
+	emake "DESTDIR=${D}" install-exec
+	popd || die
+	emake "DESTDIR=${D}" install-exec
+	if use doc ; then
+		emake "DESTDIR=${D}" install-man
+	fi
+
+	# there is currently a bug in upstream autotooling that continues to build static libraries despite
+	# explicit configure options
+	use static-libs || find "${ED}"/usr -name '*.la' -delete
+
+	einstalldocs
+}