app-emulation/protontricks: re-enable tests

Instead of having to jump through hoops to satisfy setuptools-scm,
remove references to that package and seed the version file manually,
using the value of ${PV}. Presto, can use GitHub release archives -
and by extension run tests - again!

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 58 insertions, 0 deletions

diff --git a/app-emulation/protontricks/protontricks-1.4.1-r1.ebuild b/app-emulation/protontricks/protontricks-1.4.1-r1.ebuild
new file mode 100644
index 000000000000..d17ef1b45996
--- /dev/null
+++ b/app-emulation/protontricks/protontricks-1.4.1-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="app-emulation/winetricks wrapper for Proton (Steam Play) games"
+HOMEPAGE="https://github.com/Matoking/protontricks"
+# Will remove the .gh bit come next version bump
+SRC_URI="https://github.com/Matoking/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+gui"
+
+RDEPEND="app-emulation/winetricks
+	$(python_gen_cond_dep '
+		dev-python/vdf[${PYTHON_USEDEP}]
+	')
+	gui? ( gnome-extra/zenity
+		|| (
+			app-emulation/winetricks[gtk]
+			app-emulation/winetricks[kde]
+		)
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.1_no-setuptools-scm.patch
+)
+
+DOCS=( CHANGELOG.md README.md )
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+	sed -i -e "s/@VERSION@/${PV}/" "${S}"/src/${PN}/_version.py || die
+}
+
+pkg_postinst() {
+	elog
+
+	if ! use gui; then
+		ewarn "Please note that disabling USE=gui does *not* presently remove the --gui command-line option,"
+		ewarn "it just means using this option will fail unless gnome-extra/zenity happens to be installed."
+		ewarn
+	fi
+
+	elog "Protontricks can only find games for which a Proton prefix already exists."
+	elog "Make sure to run a Proton game at least once before trying to use protontricks on it."
+	elog
+}