app-emulation/protontricks: bump to 1.4.1

protontricks now have a setup-time dependency on
dev-python/setuptools_scm, which means we have to use use release
tarballs from PyPI rather than from GitHub - the latter cause builds to
fail with

LookupError: setuptools-scm was unable to detect version for '/.../app-emulation/protontricks-1.4.1/work/protontricks-1.4.1'.
Make sure you're either building from a fully intact git repository or PyPI tarballs. Most other sources (such as GitHub's tarballs, a git checkout without the .git folder) don't contain the necessary metadata and will not work.

The upshot of the above is that we can no longer run tests because
the necessary files are not included in PyPI tarballs.

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/app-emulation/protontricks/protontricks-1.4.1.ebuild b/app-emulation/protontricks/protontricks-1.4.1.ebuild
new file mode 100644
index 000000000000..cebf432ce736
--- /dev/null
+++ b/app-emulation/protontricks/protontricks-1.4.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+DISTUTILS_SINGLE_IMPL=1
+inherit distutils-r1
+
+DESCRIPTION="app-emulation/winetricks wrapper for Proton (Steam Play) games"
+HOMEPAGE="https://github.com/Matoking/protontricks"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+gui"
+
+BDEPEND="${PYTHON_DEPS}
+	dev-python/setuptools_scm"
+RDEPEND="${PYTHON_DEPS}
+	app-emulation/winetricks
+	$(python_gen_cond_dep '
+		dev-python/vdf[${PYTHON_MULTI_USEDEP}]
+	')
+	gui? ( gnome-extra/zenity
+		|| (
+			app-emulation/winetricks[gtk]
+			app-emulation/winetricks[kde]
+		)
+	)"
+
+# Tarballs from PyPI do not contain tests, and we cannot use GitHub releases
+# any more because they are incompatible with setuptools_scm.
+RESTRICT="test"
+
+DOCS=(CHANGELOG.md README.md)
+
+pkg_postinst() {
+	elog
+
+	if ! use gui; then
+		ewarn "Please note that disabling USE=gui does *not* presently remove the --gui command-line option,"
+		ewarn "it just means using this option will fail unless gnome-extra/zenity happens to be installed."
+		ewarn
+	fi
+
+	elog "Protontricks can only find games for which a Proton prefix already exists."
+	elog "Make sure to run a Proton game at least once before trying to use protontricks on it."
+	elog
+}