app-emulation/skopeo: 0.2.0 bump

Signed-off-by: William Hubbs <williamh@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/app-emulation/skopeo/skopeo-0.2.0.ebuild b/app-emulation/skopeo/skopeo-0.2.0.ebuild
new file mode 100644
index 000000000000..41797bfbd1bb
--- /dev/null
+++ b/app-emulation/skopeo/skopeo-0.2.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+COMMIT=1119299c4b27e16680744e8bcf3b5362344a40d7
+inherit go-module bash-completion-r1
+
+DESCRIPTION="Command line utility foroperations on container images and image repositories"
+HOMEPAGE="https://github.com/containers/skopeo"
+SRC_URI="https://github.com/containers/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+COMMON_DEPEND=">=app-crypt/gpgme-1.5.5:=
+	>=dev-libs/libassuan-2.4.3:=
+	dev-libs/libgpg-error:=
+	>=sys-fs/btrfs-progs-4.0.1
+	>=sys-fs/lvm2-2.02.145:="
+DEPEND="${COMMON_DEPEND}
+	dev-go/go-md2man"
+RDEPEND="${COMMON_DEPEND}"
+
+RESTRICT="test"
+
+src_compile() {
+	local BUILDTAGS="containers_image_ostree_stub"
+	set -- go build -mod=vendor -ldflags "-X main.gitCommit=${COMMIT}" \
+		-gcflags "${GOGCFLAGS}" -tags "${BUILDTAGS}" \
+		-o skopeo ./cmd/skopeo
+	echo "$@"
+	"$@" || die
+	cd docs || die
+	for f in *.1.md; do
+		go-md2man -in ${f} -out ${f%%.md} || die
+	done
+}
+
+src_install() {
+	dobin skopeo
+	doman docs/*.1
+	dobashcomp completions/bash/skopeo
+	insinto /etc/containers
+	newins default-policy.json policy.json
+	insinto /etc/containers/registries.d
+	doins default.yaml
+	keepdir /var/lib/atomic/sigstore
+	einstalldocs
+}