app-i18n/librime: Depend on dev-libs/boost:=[threads(+)]

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 74 insertions, 0 deletions

diff --git a/app-i18n/librime/librime-1.6.0-r1.ebuild b/app-i18n/librime/librime-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..77cc61ea01a8
--- /dev/null
+++ b/app-i18n/librime/librime-1.6.0-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2012-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit cmake
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/rime/librime"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="RIME (Rime Input Method Engine) core library"
+HOMEPAGE="https://rime.im/ https://github.com/rime/librime"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/rime/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/1-${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="dev-libs/capnproto:0"
+RDEPEND="app-i18n/opencc:0=
+	>=dev-cpp/glog-0.3.5:0=
+	dev-cpp/yaml-cpp:0=
+	dev-libs/boost:0=[threads(+)]
+	dev-libs/capnproto:0=
+	dev-libs/leveldb:0=
+	dev-libs/marisa:0="
+DEPEND="${RDEPEND}
+	dev-libs/darts
+	dev-libs/utfcpp
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )"
+
+DOCS=(CHANGELOG.md README.md)
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-1.6.0-boost-1.76.patch"
+	eapply "${FILESDIR}/${PN}-1.6.0-plugins.patch"
+
+	# Use headers of dev-libs/darts, dev-libs/utfcpp and x11-base/xorg-proto.
+	sed -e "/\${PROJECT_SOURCE_DIR}\/thirdparty/d" -i CMakeLists.txt || die
+	rm -r thirdparty || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local -x CXXFLAGS="${CXXFLAGS} -I${ESYSROOT}/usr/include/utf8cpp"
+
+	if use debug; then
+		CXXFLAGS+=" -DDCHECK_ALWAYS_ON"
+	else
+		CXXFLAGS+=" -DNDEBUG"
+	fi
+
+	local mycmakeargs=(
+		-DBOOST_USE_CXX11=ON
+		-DBUILD_TEST=$(usex test ON OFF)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Gflags=ON
+		-DENABLE_EXTERNAL_PLUGINS=ON
+		-DINSTALL_PRIVATE_HEADERS=ON
+	)
+
+	cmake_src_configure
+}