app-metrics/pushgateway: Version bump to 0.10.0

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/app-metrics/pushgateway/pushgateway-0.10.0.ebuild b/app-metrics/pushgateway/pushgateway-0.10.0.ebuild
new file mode 100644
index 000000000000..5ab0a518e0de
--- /dev/null
+++ b/app-metrics/pushgateway/pushgateway-0.10.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit user golang-build golang-vcs-snapshot systemd
+
+EGO_PN="github.com/prometheus/pushgateway"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+GIT_COMMIT="b73d22c"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Prometheus push acceptor for ephemeral and batch jobs"
+HOMEPAGE="https://github.com/prometheus/pushgateway"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0 BSD BSD-2 MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND=">=dev-lang/go-1.12
+	>=dev-util/promu-0.3.0"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${GIT_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GO111MODULE=on GOPATH="${S}" promu build -v --prefix bin || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin bin/pushgateway
+	dodoc {README,CHANGELOG,CONTRIBUTING}.md
+	popd || die
+	keepdir /var/lib/${PN} /var/log/${PN}
+	fowners ${PN}:${PN} /var/lib/${PN} /var/log/${PN}
+	newinitd "${FILESDIR}"/${PN}-1.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}-1.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}-1.service"
+}