app-misc/anki: bump to 2.1.15 and modernize ebuild

 - claiming maintainer timeout to update version and fix bugs, --juippis

 * Bump to EAPI 7
 * Enable python 3.{7,8} support
 * Fix missing test dependencies
 * Add missing jsonschema dependency
 * Backport argument fix to allow mpv versions > 0.31 to be used by anki
 * Correct and expand LICENSE
 * Resolve NonexistentDeps DEPEND warning (leftover from PyQtWebEngine split,
   but no version of PyQt5 with a webengine use flag is still in the tree.)
 * Use default pkg_setup from eclass and rely on default value for S variable
 * Clarify optional runtime dependencies needed (mpv OR mplayer)
 * Move optional runtime dependencies to optfeature
 * Adjust SRC_URL after upstream re-arranging

NOTE: The upstream LICENSE includes "Qt's bundled translations: LGPL3", but
since we are building from source that is not directly included.  More recent
upstream versions have clarified this in the LICENSE file.

Bug: https://bugs.gentoo.org/625894
Bug: https://bugs.gentoo.org/645314
Bug: https://bugs.gentoo.org/651472
Bug: https://bugs.gentoo.org/688798
Closes: https://bugs.gentoo.org/700010
Closes: https://bugs.gentoo.org/715624
Bug: https://bugs.gentoo.org/722502
Bug: https://bugs.gentoo.org/724482
Bug: https://bugs.gentoo.org/724990
Closes: https://bugs.gentoo.org/726522

Signed-off-by: Chris Burroughs <chris.burroughs@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/16054
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 93 insertions, 0 deletions

diff --git a/app-misc/anki/anki-2.1.15.ebuild b/app-misc/anki/anki-2.1.15.ebuild
new file mode 100644
index 000000000000..2f651f60f1dc
--- /dev/null
+++ b/app-misc/anki/anki-2.1.15.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+PYTHON_REQ_USE="sqlite"
+
+inherit desktop eutils python-single-r1 xdg
+
+DESCRIPTION="A spaced-repetition memory training program (flash cards)"
+HOMEPAGE="https://apps.ankiweb.net"
+SRC_URI="https://apps.ankiweb.net/downloads/archive/${P}-source.tgz -> ${P}.tgz"
+
+LICENSE="AGPL-3+ BSD MIT GPL-3+ CC-BY-SA-3.0 Apache-2.0 CC-BY-2.5"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/PyQt5-5.12[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQtWebEngine-5.12[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/httplib2-0.7.4[${PYTHON_MULTI_USEDEP}]
+		dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
+		dev-python/decorator[${PYTHON_MULTI_USEDEP}]
+		dev-python/jsonschema[${PYTHON_MULTI_USEDEP}]
+		dev-python/markdown[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+		dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
+	')
+"
+BDEPEND="test? (
+	${RDEPEND}
+	$(python_gen_cond_dep '
+		dev-python/nose[${PYTHON_MULTI_USEDEP}]
+		dev-python/mock[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch
+	"${FILESDIR}"/${PN}-2.1.15-mpv-args.patch
+)
+
+src_prepare() {
+	default
+	sed -i -e "s/updates=True/updates=False/" \
+		aqt/profiles.py || die
+}
+
+src_compile() {
+	:;
+}
+
+src_test() {
+	sed -e "s:nose=nosetests$:nose=\"${EPYTHON} ${EROOT}/usr/bin/nosetests\":" \
+		-i tools/tests.sh || die
+	sed -e "s:nose=nosetests3$:nose=\"${EPYTHON} ${EROOT}/usr/bin/nosetests3\":" \
+		-i tools/tests.sh || die
+	sed -e "s:which nosetests3:which ${EROOT}/usr/bin/nosetests3:" \
+		-i tools/tests.sh || die
+	./tools/tests.sh || die
+}
+
+src_install() {
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+	doman ${PN}.1
+
+	dodoc README.md README.development
+	python_domodule aqt anki
+	python_newscript runanki anki
+
+	# Localization files go into the anki directory:
+	python_moduleinto anki
+	python_domodule locale
+
+	# not sure if this is correct, but
+	# site-packages/aqt/mediasrv.py wants the directory
+	insinto /usr/share/anki
+	doins -r web
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "LaTeX in cards" "app-text/texlive app-text/dvipng"
+	optfeature "Record sound" "dev-python/pyaudio media-sound/lame"
+	optfeature "Playback sound" media-video/mpv media-video/mplayer
+}