app-misc/g15stats: EAPI-7 revbump

- Fixed docdir

Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/app-misc/g15stats/g15stats-1.9.7-r1.ebuild b/app-misc/g15stats/g15stats-1.9.7-r1.ebuild
new file mode 100644
index 000000000000..199760efdca1
--- /dev/null
+++ b/app-misc/g15stats/g15stats-1.9.7-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="CPU, memory, swap, network stats for G15 Keyboard"
+HOMEPAGE="https://sourceforge.net/projects/g15daemon/"
+SRC_URI="mirror://sourceforge/g15daemon/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=app-misc/g15daemon-1.9.0
+	dev-libs/libg15
+	dev-libs/libg15render
+	sys-libs/zlib
+	gnome-base/libgtop"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}/${P}-docdir.patch" )
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	export CPPFLAGS="${CFLAGS}"
+	econf
+}
+
+src_install() {
+	default
+	rm "${D}"/usr/share/doc/${PF}/{COPYING,NEWS} || die
+
+	newconfd "${FILESDIR}/${PN}-1.9.7.confd" ${PN}
+	newinitd "${FILESDIR}/${PN}-1.9.7.initd" ${PN}
+}
+
+pkg_postinst() {
+	elog "Remember to set the interface you want monitored in"
+	elog "/etc/conf.d/g15stats"
+}