proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 73 insertions, 0 deletions

diff --git a/app-misc/oneko/oneko-1.2-r2.ebuild b/app-misc/oneko/oneko-1.2-r2.ebuild
new file mode 100644
index 000000000000..76fc65a8d762
--- /dev/null
+++ b/app-misc/oneko/oneko-1.2-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
+HOMEPAGE="http://www.daidouji.com/oneko/"
+SRC_URI="http://www.daidouji.com/oneko/distfiles/${P}.sakura.5.tar.gz
+	mirror://gentoo/${P}-cat.png
+	mirror://gentoo/${P}-dog.png
+	mirror://gentoo/${P}-sakura-nobsd.patch.bz2"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="amd64 ppc ppc64 x86"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+"
+DEPEND="
+	${RDEPEND}
+	x11-misc/gccmakedep
+	x11-misc/imake
+	app-text/rman
+	x11-proto/xextproto
+"
+
+S=${WORKDIR}/oneko-${PV}.sakura.5
+
+src_prepare() {
+	epatch \
+		"${WORKDIR}"/${P}-sakura-nobsd.patch \
+		"${FILESDIR}"/${P}-include.patch
+}
+
+src_configure() {
+	xmkmf -a || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CCOPTIONS="${CFLAGS}" \
+		EXTRA_LDOPTIONS="${LDFLAGS}" \
+		|| die
+}
+
+src_install() {
+	dobin oneko
+	newman oneko._man oneko.1x
+	dodoc README README-NEW README-SUPP
+	newicon "${DISTDIR}/${P}-cat.png" "cat.png"
+	newicon "${DISTDIR}/${P}-dog.png" "dog.png"
+	make_desktop_entry "oneko" "oneko (cat)" "cat" "Game;Amusement"
+	make_desktop_entry "oneko -dog" "oneko (dog)" "dog" "Game;Amusement"
+	make_desktop_entry "killall -TERM oneko" "oneko kill" "" "Game;Amusement"
+}
+
+pkg_postinst() {
+	elog "To kill oneko, type the following in a terminal:"
+	elog ""
+	elog "killall oneko"
+	elog ""
+	elog "If your mouse cursor changes to the default black cross"
+	elog "after running ${PN}, you should emerge x11-apps/xsetroot"
+	elog "and run:"
+	elog ""
+	elog "xsetroot -cursor_name left_ptr"
+	elog ""
+}