app-misc/pdfpc: Bump to 4.5.0 (new license: GPL-3+)

This bump pdfpc to 4.5.0 which is relicensed to GPL-3 or newer:
https://github.com/pdfpc/pdfpc/commit/2a2c9b71467db801a3a0c6e5aabc8794004216bb

Full Changelog for 4.5.0

    Switch to GPLv3+ licence
    JSON format for pdfpc file
    Markdown support for text notes
    Render LaTeX beamer and text notes in the same place
    Per-overlay notes
    Zoom feature in highlighted areas
    Spotlight mode
    Page transitions
    Automatic slide advancing
    Video controls in presentation window
    Max/unmax current slide view in presenter
    Consistency with pdfpc/command line overriding of options
    Allow run-time GUI customization
    Assorted bug fixes

Note that the non-optional markdown support pulls in webkit-gtk.

Closes: https://bugs.gentoo.org/810333
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Nils Freydank <holgersson@posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/22154
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 76 insertions, 0 deletions

diff --git a/app-misc/pdfpc/pdfpc-4.5.0.ebuild b/app-misc/pdfpc/pdfpc-4.5.0.ebuild
new file mode 100644
index 000000000000..f8a142ef1ce1
--- /dev/null
+++ b/app-misc/pdfpc/pdfpc-4.5.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+VALA_MIN_API_VERSION="0.44"
+VALA_MAX_API_VERSION="0.50" # append versions in sed line if increased
+
+COMMIT_ID=""
+
+inherit cmake vala
+
+DESCRIPTION="Presenter console with multi-monitor support for PDF files"
+HOMEPAGE="https://pdfpc.github.io https://github.com/pdfpc/pdfpc"
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+gstreamer"
+KEYWORDS="~amd64 ~x86"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}/.git"
+	inherit git-r3
+else
+	if [[ ${PV} == *_p* ]]; then
+		SRC_URI="https://github.com/${PN}/${PN}/archive/${COMMIT_ID}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${PN}-${COMMIT_ID}"
+	else
+		SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+fi
+
+RDEPEND="
+	app-text/discount
+	app-text/poppler:=[cairo]
+	dev-libs/glib:2
+	dev-libs/libgee:0.8=
+	gnome-base/librsvg
+	net-libs/webkit-gtk:4
+	sys-apps/dbus
+	x11-libs/gtk+:3
+	gstreamer? (
+		media-libs/gstreamer:1.0=
+		media-libs/gst-plugins-base:1.0=
+		media-plugins/gst-plugins-gtk:1.0=
+		media-plugins/gst-plugins-cairo:1.0=
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="$(vala_depend)"
+
+DOCS=(
+	CHANGELOG.rst
+	FAQ.rst
+	README.rst
+	SUPPORT.rst
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i -e "s/valac/valac valac-0.50 valac-0.48 valac-0.46 valac-0.44/" cmake/vala/FindVala.cmake || die
+	vala_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DMOVIES=$(usex gstreamer on off)
+		-DCMAKE_VERBOSE_MAKEFILE=TRUE
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	einstalldocs
+}