app-misc/when: version bump to 1.1.37

1 files changed, 41 insertions, 0 deletions

diff --git a/app-misc/when/when-1.1.37.ebuild b/app-misc/when/when-1.1.37.ebuild
new file mode 100644
index 000000000000..533d342eb72f
--- /dev/null
+++ b/app-misc/when/when-1.1.37.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DESCRIPTION="Minimalistic personal calendar program"
+HOMEPAGE="http://www.lightandmatter.com/when/when.html"
+SRC_URI="http://www.lightandmatter.com/when/when.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Artistic"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+
+DEPEND="dev-lang/perl"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/when_dist"
+
+DOCS=( README )
+
+src_prepare() {
+	default
+
+	# Fix path for tests
+	sed -i 's,^	when,	./when,' Makefile || die 'sed failed'
+}
+
+src_compile() { :; }
+
+src_test() {
+	# The when command requires these files, or attempts to run setup function.
+	mkdir "${HOME}"/.when || die 'mkdir failed'
+	touch "${HOME}"/.when/{calendar,preferences} || die 'touch failed'
+	emake test
+}
+
+src_install() {
+	dobin "${PN}"
+	doman "${PN}.1"
+	einstalldocs
+}