app-misc/ddcutil: Version bump to 0.9.5

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Manuel Rüger <mrueg@gentoo.org>

2 files changed, 107 insertions, 0 deletions

diff --git a/app-misc/ddcutil/Manifest b/app-misc/ddcutil/Manifest
index 886483f6e13b..e60f5f8da788 100644
--- a/app-misc/ddcutil/Manifest
+++ b/app-misc/ddcutil/Manifest
@@ -1 +1,2 @@
 DIST ddcutil-0.9.1.tar.gz 656853 BLAKE2B e4f11253176587cb5ee3c9647a01ab04d5a92ce4ca7a4098378318fc069e635e43c3716ace316498f64ceaaa00aa90db3b5f409b74b8d7089a7c25254c0e360d SHA512 b2d5866606a4bc081d89180e910822f2a2a653a2782e3df582536ddc86c7d3dc02309dbb41f8d566f6ebdc5d82d3aa11792a04c28b3d83552b024dfd59891fda
+DIST ddcutil-0.9.5.tar.gz 681534 BLAKE2B 6746c239738d4f8eb7fe56323816fadee9b8fa9ad2b66a8242782e0b2688182c0140b40b9eddb3b54ad32c7ff7d1f0cf9a28c5477a48d90cc39431ed82f5d443 SHA512 6249ebdbb398ad5a6c32f3891be8bf5328114b1ed08afd75adf4b67f10a40f19451e188ce5cd88b3153a18f317e394146a34258a7d2298f126be227d7e1c25e8
diff --git a/app-misc/ddcutil/ddcutil-0.9.5.ebuild b/app-misc/ddcutil/ddcutil-0.9.5.ebuild
new file mode 100644
index 000000000000..a0f3bc6bf4da
--- /dev/null
+++ b/app-misc/ddcutil/ddcutil-0.9.5.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools flag-o-matic linux-info udev user
+
+DESCRIPTION="Program for querying and changing monitor settings"
+HOMEPAGE="http://www.ddcutil.com/"
+SRC_URI="https://github.com/rockowitz/ddcutil/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="drm usb-monitor user-permissions video_cards_nvidia X"
+REQUIRED_USE="drm? ( X )"
+
+RDEPEND="dev-libs/glib:2
+	sys-apps/i2c-tools
+	virtual/udev
+	drm? ( x11-libs/libdrm )
+	usb-monitor? (
+		dev-libs/hidapi
+		virtual/libusb:1
+		sys-apps/usbutils
+	)
+	X? (
+		x11-libs/libXrandr
+		x11-libs/libX11
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+pkg_pretend() {
+	# This program needs /dev/ic2-* devices to communicate with the monitor.
+	CONFIG_CHECK="~I2C_CHARDEV"
+	ERROR_I2C_CHARDEV="You must enable I2C_CHARDEV in your kernel to continue"
+	if use usb-monitor; then
+		CONFIG_CHECK+=" ~HIDRAW ~USB_HIDDEV"
+		ERROR_HIDRAW="HIDRAW is needed to support USB monitors"
+		ERROR_I2C_CHARDEV="USB_HIDDEV is needed to support USB monitors"
+	fi
+
+	# Now do the actual checks setup above
+	check_extra_config
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Bug 607818.
+	replace-flags -O3 -O2
+
+	local myeconfargs=(
+		$(use_enable drm)
+		$(use_enable usb-monitor usb)
+		$(use_enable X x11)
+		--enable-lib
+		--disable-cffi
+		--disable-cython
+		--disable-swig
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	if use user-permissions; then
+		udev_dorules data/etc/udev/rules.d/45-ddcutil-i2c.rules
+		if use usb-monitor; then
+			udev_dorules data/etc/udev/rules.d/45-ddcutil-usb.rules
+		fi
+	fi
+}
+
+pkg_postinst() {
+	if use user-permissions; then
+		enewgroup i2c
+		einfo "To allow non-root users access to the /dev/i2c-* devices, add those"
+		einfo "users to the i2c group: usermod -aG i2c user"
+		einfo "Restart the computer or reload the i2c-dev module to activate"
+		einfo "the new udev rule."
+		einfo "For more information read: http://www.ddcutil.com/i2c_permissions/"
+
+		if use usb-monitor; then
+			enewgroup video
+			einfo "To allow non-root users access to USB monitors, add those users"
+			einfo "to the video group: usermod -aG video user"
+			einfo "Restart the computer, reload the hiddev and hidraw modules, or replug"
+			einfo "the monitor to activate the new udev rule."
+			einfo "For more information read: http://www.ddcutil.com/usb/"
+		fi
+
+		udev_reload
+	fi
+
+	if use video_cards_nvidia; then
+		ewarn "Please read the following webpage on proper usage with the nVidia "
+		ewarn "binary drivers, or it may not work: http://www.ddcutil.com/nvidia/"
+	fi
+}