app-office/gtg: bump to 0.5

Closes: https://bugs.gentoo.org/788868
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/app-office/gtg/gtg-0.5.ebuild b/app-office/gtg/gtg-0.5.ebuild
new file mode 100644
index 000000000000..a2e3580997f6
--- /dev/null
+++ b/app-office/gtg/gtg-0.5.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python3_8 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="Personal organizer for the GNOME desktop environment"
+HOMEPAGE="https://wiki.gnome.org/Apps/GTG/"
+SRC_URI="https://github.com/getting-things-gnome/gtg/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		>=dev-python/liblarch-3.1.0[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	x11-libs/pango[introspection]
+	x11-libs/gdk-pixbuf[introspection]
+	x11-libs/gtk+:3[introspection]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	test? ( $(python_gen_cond_dep '
+			dev-python/nose[${PYTHON_USEDEP}]
+			dev-python/cheetah3[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+		')
+		app-text/pdfjam
+		app-text/pdftk
+		dev-texlive/texlive-latex
+	)
+"
+
+PATCHES=(
+	# Fixes tests, and mouse cursor with some themes
+	"${FILESDIR}"/${PV}-mouse-cursor-fixes{1,2,3}.patch
+)
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"/usr/bin/gtg
+	python_optimize
+}
+
+src_test() {
+	sed -e "s|@VCS_TAG@|${PV}|" GTG/core/info.py.in > GTG/core/info.py || die
+	nosetests -v || die
+}