proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 60 insertions, 0 deletions

diff --git a/app-text/dvipdfm/dvipdfm-0.13.2d-r2.ebuild b/app-text/dvipdfm/dvipdfm-0.13.2d-r2.ebuild
new file mode 100644
index 000000000000..7d57640d86be
--- /dev/null
+++ b/app-text/dvipdfm/dvipdfm-0.13.2d-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=3
+inherit eutils
+
+DESCRIPTION="DVI to PDF translator"
+SRC_URI="http://gaspra.kettering.edu/dvipdfm/${P}.tar.gz"
+HOMEPAGE="http://gaspra.kettering.edu/dvipdfm/"
+LICENSE="GPL-2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+SLOT="0"
+IUSE=""
+
+DEPEND="!>=app-text/tetex-2
+	>=media-libs/libpng-1.2.1
+	>=sys-libs/zlib-1.1.4
+	!app-text/ptex
+	virtual/latex-base"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-libpng14.patch
+}
+
+src_install () {
+	einstall texmf="${ED}usr/share/texmf-site" || die "einstall failed!"
+
+	# Install .map and .enc files to correct locations, bug #200956
+	dodir /usr/share/texmf-site/fonts/map/dvipdfm/base
+
+	for i in cmr.map psbase14.map lw35urw.map lw35urwa.map t1fonts.map; do
+		mv "${ED}usr/share/texmf-site/dvipdfm/config/${i}" "${ED}usr/share/texmf-site/fonts/map/dvipdfm/base" || die "moving .map file failed"
+	done
+
+	dodir /usr/share/texmf-site/fonts/enc/dvipdfm
+
+	mv "${ED}usr/share/texmf-site/dvipdfm/base" "${ED}usr/share/texmf-site/fonts/enc/dvipdfm/base" || die "moving .enc file failed"
+
+	dodoc AUTHORS ChangeLog Credits NEWS OBTAINING README* TODO
+
+	docinto doc
+	dodoc doc/*
+
+	docinto latex-support
+	dodoc latex-support/*
+
+	insinto /usr/share/texmf-site/tex/latex/dvipdfm/
+	doins latex-support/dvipdfm.def
+}
+
+pkg_postinst() {
+	if [ "$ROOT" = "/" ] ; then
+		"${EPREFIX}"/usr/sbin/texmf-update
+	fi
+}