app-text/poppler: Drop 21.10.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 0 insertions, 127 deletions

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index a0b246e9a2eb..09d278d38b3b 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,3 +1,2 @@
 DIST poppler-21.07.0.tar.xz 1709664 BLAKE2B 22c411c44a7f61344a0ea747fd435ad2b0180979d8117425167338b7f5cf963eefac19d38b5630df03b4ef978a113c9f031966d3bd8b0c1d86a5bdecd526d191 SHA512 ce1d8a5dd4a300a24aa71aea4919262e108ce1717dee04863da41de0962e4c0067e9c703c190386bd66d9c4ef54d04513cc8509f4beaf76e996576912d2583e8
-DIST poppler-21.10.0.tar.xz 1779668 BLAKE2B f4464b70ba031ed697443803c435a79498184fc9a74381f5ac7c6ee0f856d77d6e270fe0cea70ee9bbc54713ec69d45ea0ffc66e820d80061856d6711d584e04 SHA512 4a125784716ee578f5be39830cc5903c27eeb707d3756c2ff04ef97328ed8d9e35d3873b7731d2144997cb31794674a1bd35461c84d4237335db27c8df43e4f1
 DIST poppler-21.11.0.tar.xz 1783592 BLAKE2B b0448ae0456ffda29c18732e6dd94cb285af67cf4adbaded05a4abe2e465cb63a17e0041240c82c83c89b313ec8c7bf9d68fc8d727b7d41c1ee70722529ce45d SHA512 354d6372093e7ecedf95c43e8d203e9b2781ff7ecd81cd3920cb8c72a37463b47423ce7ab3c8233c0f031f2c024ac1ba5c8d442c80e6643722192fb9638e5d3a
diff --git a/app-text/poppler/poppler-21.10.0.ebuild b/app-text/poppler/poppler-21.10.0.ebuild
deleted file mode 100644
index 2ca5838c2b0a..000000000000
--- a/app-text/poppler/poppler-21.10.0.ebuild
+++ /dev/null
@@ -1,126 +0,0 @@
-# Copyright 2005-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake toolchain-funcs xdg-utils
-
-if [[ ${PV} == *9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
-	SLOT="0/9999"
-else
-	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-	SLOT="0/114"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
-fi
-
-DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
-HOMEPAGE="https://poppler.freedesktop.org/"
-
-LICENSE="GPL-2"
-IUSE="boost cairo cjk curl +cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
-
-# No test data provided
-RESTRICT="test"
-
-DEPEND="
-	media-libs/fontconfig
-	media-libs/freetype
-	sys-libs/zlib
-	cairo? (
-		dev-libs/glib:2
-		x11-libs/cairo
-		introspection? ( dev-libs/gobject-introspection:= )
-	)
-	curl? ( net-misc/curl )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
-	lcms? ( media-libs/lcms:2 )
-	nss? ( >=dev-libs/nss-3.19:0 )
-	png? ( media-libs/libpng:0= )
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtxml:5
-	)
-	tiff? ( media-libs/tiff:0 )
-"
-RDEPEND="${DEPEND}
-	cjk? ( app-text/poppler-data )
-"
-DEPEND+="
-	boost? ( dev-libs/boost )
-"
-BDEPEND="
-	dev-util/glib-utils
-	virtual/pkgconfig
-"
-
-DOCS=( AUTHORS NEWS README.md README-XPDF )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-20.12.1-qt5-deps.patch"
-	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
-	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# Clang doesn't grok this flag, the configure nicely tests that, but
-	# cmake just uses it, so remove it if we use clang
-	if tc-is-clang ; then
-		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
-	fi
-
-	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
-		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
-			-i CMakeLists.txt || die
-	else
-		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
-	fi
-}
-
-src_configure() {
-	xdg_environment_reset
-	local mycmakeargs=(
-		-DBUILD_GTK_TESTS=OFF
-		-DBUILD_QT5_TESTS=OFF
-		-DBUILD_CPP_TESTS=OFF
-		-DBUILD_MANUAL_TESTS=OFF
-		-DRUN_GPERF_IF_PRESENT=OFF
-		-DENABLE_BOOST="$(usex boost)"
-		-DENABLE_ZLIB=ON
-		-DENABLE_ZLIB_UNCOMPRESS=OFF
-		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
-		-DUSE_FLOAT=OFF
-		-DWITH_Cairo=$(usex cairo)
-		-DENABLE_LIBCURL=$(usex curl)
-		-DENABLE_CPP=$(usex cxx)
-		-DWITH_JPEG=$(usex jpeg)
-		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
-		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
-		-DENABLE_CMS=$(usex lcms lcms2 none)
-		-DWITH_NSS3=$(usex nss)
-		-DWITH_PNG=$(usex png)
-		$(cmake_use_find_package qt5 Qt5Core)
-		-DWITH_TIFF=$(usex tiff)
-		-DENABLE_UTILS=$(usex utils)
-		-DENABLE_QT6=OFF
-	)
-	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	# live version doesn't provide html documentation
-	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
-		# For now install gtk-doc there
-		insinto /usr/share/gtk-doc/html/poppler
-		doins -r "${S}"/glib/reference/html/*
-	fi
-}