app-text/xapian-omega: version bump to 1.4.17

Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Anthony G. Basile <blueness@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/app-text/xapian-omega/xapian-omega-1.4.17.ebuild b/app-text/xapian-omega/xapian-omega-1.4.17.ebuild
new file mode 100644
index 000000000000..f76f70d1acab
--- /dev/null
+++ b/app-text/xapian-omega/xapian-omega-1.4.17.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="An application built on Xapian, consisting of indexers and a CGI search frontend"
+SRC_URI="http://www.oligarchy.co.uk/xapian/${PV}/xapian-omega-${PV}.tar.xz"
+HOMEPAGE="https://xapian.org/"
+S="${WORKDIR}/xapian-omega-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+DEPEND="dev-libs/xapian:0/30
+	dev-lang/perl
+	dev-libs/libpcre
+	sys-libs/zlib"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	# Protect /etc/omega.conf
+	echo "CONFIG_PROTECT=\"/etc/omega.conf\"" > "${T}"/20xapian-omega
+	doenvd "${T}"/20xapian-omega
+	dodoc AUTHORS ChangeLog INSTALL NEWS README TODO
+
+	# Directory containing Xapian databases:
+	keepdir /var/lib/omega/data
+
+	# Directory containing OmegaScript templates:
+	keepdir /var/lib/omega/templates
+	mv "${S}"/templates/* "${D}"/var/lib/omega/templates || die
+
+	# Directory to write Omega logs to:
+	keepdir /var/log/omega
+
+	# Directory containing any cdb files for the $lookup OmegaScript command:
+	keepdir /var/lib/omega/cdb
+}