proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 88 insertions, 0 deletions

diff --git a/app-text/xiphos/xiphos-3.2.2.ebuild b/app-text/xiphos/xiphos-3.2.2.ebuild
new file mode 100644
index 000000000000..c5d5720b5819
--- /dev/null
+++ b/app-text/xiphos/xiphos-3.2.2.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+# TODO: waf-utils.eclass ?
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit flag-o-matic gnome2-utils python-single-r1 toolchain-funcs
+
+DESCRIPTION="A bible study frontend for Sword (formerly known as GnomeSword)"
+HOMEPAGE="http://xiphos.org/"
+SRC_URI="mirror://sourceforge/gnomesword/${P}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.1 LGPL-2 MIT MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="dbus debug"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=app-text/sword-1.7.3
+	>=dev-libs/glib-2[${PYTHON_USEDEP}]
+	dev-libs/libxml2[${PYTHON_USEDEP}]
+	gnome-base/gconf[${PYTHON_USEDEP}]
+	gnome-extra/gtkhtml:4.0
+	>=gnome-extra/libgsf-1.14
+	net-libs/webkit-gtk:3
+	x11-libs/gtk+:3
+	dbus? ( dev-libs/dbus-glib )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook2X
+	app-text/gnome-doc-utils[${PYTHON_USEDEP}]
+	app-text/rarian
+	dev-libs/libxslt[${PYTHON_USEDEP}]
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i \
+		-e '/FLAGS_DEBUG/s:-g:-Wall:' \
+		-e '/FLAGS_RELEASE/s:-O2:-Wall:' \
+		wscript || die
+}
+
+src_configure() {
+	append-cppflags -DNO_SWORD_SET_RENDER_NOTE_NUMBERS=1
+
+	tc-export AR CC CPP CXX RANLIB
+
+	CCFLAGS="${CFLAGS}" \
+	LINKFLAGS="${LDFLAGS}" \
+	SGML2MAN="$(type -P docbook2man.pl)" \
+		./waf -v \
+			--prefix=/usr \
+			--gtk=3 \
+			--debug-level=$(use debug && echo debug || echo release) \
+			$(use dbus || echo --disable-dbus) \
+			configure || die
+}
+
+src_compile() {
+	./waf -v build || die
+}
+
+src_install() {
+	./waf -v --destdir="${D}" install || die
+
+	doman ${PN}.1
+	dodoc AUTHORS ChangeLog README RELEASE-NOTES TODO
+
+	dodoc Xiphos.ogg
+	docompress -x /usr/share/doc/${PF}/Xiphos.ogg
+
+	rm -rf "${ED}"/usr/share/doc/${PN}
+}
+
+pkg_preinst() {	gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }