dev-cpp/catch: Version bump to 2.13.4

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: David Seifert <soap@gentoo.org>

1 files changed, 44 insertions, 0 deletions

diff --git a/dev-cpp/catch/catch-2.13.4.ebuild b/dev-cpp/catch/catch-2.13.4.ebuild
new file mode 100644
index 000000000000..d59bb07bc66a
--- /dev/null
+++ b/dev-cpp/catch/catch-2.13.4.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit cmake python-any-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/catchorg/Catch2.git"
+else
+	MY_P=${PN^}2-${PV}
+	SRC_URI="https://github.com/catchorg/Catch2/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Modern C++ header-only framework for unit-tests"
+HOMEPAGE="https://github.com/catchorg/Catch2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCATCH_ENABLE_WERROR=OFF
+		-DBUILD_TESTING=$(usex test)
+	)
+	use test &&
+		mycmakeargs+=(-DPYTHON_EXECUTABLE="${PYTHON}")
+
+	cmake_src_configure
+}